blob: 215579f9c9e7e33e2ff195941a1f360ea895d91d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Dmytro Bagrii <dimich.dmb@gmail.com>
# Contributor: Carlos Aznarán <caznaranl@uni.pe>
# Contributor: Antonio Rojas <arojas@archlinux.org>
# Contributor: Ronald van Haren <ronald.archlinux.org>
# Contributor: Damir Perisa <damir.perisa@bluewin.ch>
_pkgname=stellarium
pkgname=${_pkgname}-lite
pkgver=26.3
pkgrel=1
pkgdesc="Stellarium without GPS and Telescope Control support (no gpsd and libindi dependencies)"
arch=(x86_64)
url="https://${_pkgname}.org"
license=(GPL-2.0-or-later)
depends=(nlopt libpng libglvnd freetype2 openssl 'calcmysky>=0.3'
qt6-charts qt6-multimedia qt6-webengine )
makedepends=(cmake ninja mesa qt6-tools)
optdepends=('man-db: manual pages for stellarium')
conflicts=(${_pkgname})
_patches=()
source=(https://github.com/Stellarium/${_pkgname}/releases/download/v${pkgver}/${_pkgname}-${pkgver}.tar.gz{,.asc}
${_patches[@]/#/https://github.com/Stellarium/stellarium/commit/})
validpgpkeys=('79151C2E6351E7278DA1A730BF38D4D02A328DFF') # Alexander Wolf <alex.v.wolf@gmail.com>
sha256sums=('dc153809be4450e0da20099e68ec95d1b6e22f19b33cb0019588475e0d080585'
'SKIP')
prepare() {
cd ${_pkgname}-${pkgver}
for p in ${_patches[@]}; do
patch -p1 < ../$p
done
}
build() {
cmake \
-S ${_pkgname}-${pkgver} \
-B build \
-G Ninja \
-DCMAKE_BUILD_TYPE=None \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_C_COMPILER=gcc \
-DCMAKE_CXX_STANDARD=17 \
-DCMAKE_C_EXTENSIONS=Yes \
-DCMAKE_CXX_COMPILER=g++ \
-DCMAKE_C_STANDARD=17 \
-DCMAKE_CXX_EXTENSIONS=Yes \
-DENABLE_QT6=1 \
-DENABLE_SHOWMYSKY=ON \
-DENABLE_TESTING=0 \
-DENABLE_XLSX=0 \
-DENABLE_GPS=0 \
-DENABLE_MEDIA=0 \
-DUSE_PLUGIN_TELESCOPECONTROL=0 \
-Wno-author
cmake --build build --target all -- ${MAKEFLAGS}
}
package() {
DESTDIR="${pkgdir}" cmake --build build --target install
install -Dm 644 ${_pkgname}-${pkgver}/COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
find "${pkgdir}" -type d -empty -delete
}
|