PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Contributor: Lex Black <autumn-wind@web.de>

_pkgname=stevia
pkgname=stevia-git
pkgver=0.58.0.r12.g564ec21
pkgrel=1
pkgdesc='A user friendly on screen keyboard for Phosh'
arch=(i686 x86_64 arm armv6h armv7h aarch64)
url='https://gitlab.gnome.org/World/Phosh/stevia'
license=(GPL-3.0-or-later)
depends=(
  cairo
  dconf
  feedbackd
  glib2
  glibc
  gnome-desktop
  gtk3
  hunspell
  json-glib
  libgcc
  libhandy
  pango
  systemd-libs
  wayland
)
makedepends=(
  git
  glib2-devel
  meson
  wayland-protocols
)
checkdepends=(xorg-server-xvfb)
conflicts=(stevia squeekboard)
provides=(stevia phosh-osk-provider)
source=("git+https://gitlab.gnome.org/World/Phosh/stevia.git")
b2sums=('SKIP')


pkgver() {
  cd $_pkgname
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/v//'
}

build() {
  arch-meson $_pkgname -Duim=disabled -Dgovarnam=disabled build
  meson compile -C build
}

check() {
  xvfb-run meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"
}