PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Maintainer: Sid <sidpranjale127@protonmail.com>

pkgname=streamcontrol-git
pkgver=r213.c29caea
pkgrel=2
pkgdesc='App to control overlay data for Fighting Game livestreams'
arch=('i686' 'x86_64' 'aarch64')
url='http://farpnut.net/streamcontrol/'
license=('custom')
makedepends=('qt5-script' 'make')
depends=('qt5-script')
provides=('streamcontrol')
conflicts=('streamcontrol')
source=('git+https://github.com/farpenoodle/StreamControl.git'
        'streamcontrol.desktop')
sha256sums=('SKIP'
            'c91d6fc98df74304f3efea80fbd53147eca54e5e5813857fa60e268821abf684')

pkgver() {
    cd $srcdir/StreamControl/StreamControl
    echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

build() {
    cd StreamControl/StreamControl
    qmake
    make
}

package() {
    cd StreamControl/StreamControl
    install -D -t "$pkgdir"/usr/bin StreamControl
    install -D -t "$pkgdir"/usr/share/applications -m 644 "$srcdir"/streamcontrol.desktop
}