blob: 0f14ead5e29eb758a56a7392c2960c324d700cba (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Maintainer:
# Contributor: fsyy <fossy2001 at web.de>
_pkgname=streamdeck-ui
pkgname="$_pkgname-git"
pkgver=2.0.15.r8.g9b9c269
pkgrel=1
pkgdesc="A Linux compatible UI for the Elgato Stream Deck"
arch=('any')
url="https://timothycrosley.github.io/streamdeck-ui/"
license=('MIT')
depends=(
'pyside6'
'python-cairosvg'
'python-filetype'
'python-pillow'
# AUR
'python-elgato-streamdeck'
'python-pynput'
)
makedepends=(
'git'
'python-build'
'python-installer'
'python-poetry'
'python-setuptools'
'python-wheel'
)
optdepends=(
'gnome-shell-extension-appindicator: tray icon support gnome-shell'
)
provides=("$_pkgname")
conflicts=(${provides[@]})
source=(
"$_pkgname"::"git+https://github.com/timothycrosley/streamdeck-ui.git"
"60-streamdeck.rules"
)
sha256sums=(
'SKIP'
'f91b76a71ee5253bcc3dff2a096fb7c2cc8ec4f510c7a9adc4df1f0967ea3dd3'
)
pkgver() {
cd "$_pkgname"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$_pkgname"
python -m build --no-isolation --wheel
}
package() {
cd "$_pkgname"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm 644 "$srcdir/60-streamdeck.rules" -t "$pkgdir/usr/lib/udev/rules.d"
install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}
|