blob: dd306948a361bac225c555d8cc5f5baa7a8a1312 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Josip Ponjavic <josipponjavic at gmail dot com>
pkgname=streamlink-git
pkgver=0.1.0.r35.g2b052ad
pkgrel=1
pkgdesc='CLI program that launches streams from various streaming services in a custom video player (livestreamer fork)'
arch=('any')
url='https://streamlink.github.io/'
license=('BSD')
depends=('python-pycryptodome' 'python-requests' 'python-setuptools' 'rtmpdump')
checkdepends=('python-pytest')
makedepends=('git' 'python-sphinx')
optdepends=('python-librtmp: Required by the ustreamtv plugin to be able to use non-mobile streams.')
provides=('streamlink')
conflicts=('streamlink')
source=('git+https://github.com/streamlink/streamlink.git')
sha256sums=('SKIP')
pkgver() {
cd streamlink
git describe --long --tags | sed -r 's/([^-]*-g)/r\1/;s/-/./g'
}
build() {
cd streamlink
python setup.py build_sphinx -b man
}
check() {
cd streamlink
python -m pytest tests/
}
package() {
cd streamlink
python setup.py install --root="$pkgdir" --optimize=1
install -Dm644 build/sphinx/man/streamlink.1 \
"$pkgdir/usr/share/man/man1/streamlink.1"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|