summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: c9ee0096721f6600e0afc950f7c7d3554c5acee6 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
# Maintainer: Josip Ponjavic <josipponjavic at gmail dot com>

_use_pycrypto="no"
_use_pycountry="no"  

pkgname=streamlink-git
pkgver=0.4.0.r23.g951edb3
pkgrel=1
pkgdesc='CLI program that launches streams from various streaming services in a custom video player (livestreamer fork)'
arch=('any')
url='https://streamlink.github.io/'
license=('BSD')

if [ "$_use_pycrypto" = "yes" ]; then
  depends+=('python-crypto')
  conflicts+=('python-pycryptodome')
else
  depends+=('python-pycryptodome')
fi

if [ "$_use_pycountry" = "yes" ]; then
  depends+=('python-pycountry')
else
  depends+=('python-iso3166' 'python-iso639')
fi

depends+=('python-requests' 'rtmpdump')
checkdepends=("python-"{mock,pytest})
makedepends=('git' "python-"{setuptools,sphinx})
optdepends=('ffmpeg: Required to play streams that are made up of separate audio and video streams, eg. YouTube 1080p+'
            'python-librtmp: Required by the ustreamtv plugin to be able to use non-mobile streams.')
provides=('streamlink')
conflicts+=('streamlink')
source=('git+https://github.com/streamlink/streamlink.git')
sha512sums=('SKIP')

pkgver() {
  cd streamlink
  git describe --long --tags | sed -r 's/([^-]*-g)/r\1/;s/-/./g'
}

build() {
  cd streamlink
  if [ "$_use_pycrypto" = "yes" ]; then
    msg "Using pycrypto..."
    export STREAMLINK_USE_PYCRYPTO="true"
  fi
  if [ "$_use_pycountry" = "yes" ]; then
    msg "Using pycountry..."
    export STREAMLINK_USE_PYCOUNTRY="true"
  fi
  python setup.py build_sphinx -b man
}

check() {
  cd streamlink
  python setup.py test || warning "Tests failed"
}

package() {
  cd streamlink
  python setup.py install --root="$pkgdir" --optimize=1
  install -Dm644 build/sphinx/man/streamlink.1 \
    "$pkgdir/usr/share/man/man1/streamlink.1"
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}