blob: 94a75cdb7863481db68d041f04b4c7fd69b5d981 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# Maintainer: Luke Arms <luke@arms.to>
pkgname=stretchly
pkgver=1.10.0
pkgrel=1
pkgdesc="The break time reminder app"
arch=('i686' 'x86_64')
url="https://github.com/hovancik/stretchly/"
license=('BSD')
depends=('gtk3' 'libnotify' 'nss' 'libxss' 'libxtst' 'xdg-utils' 'at-spi2-atk' 'util-linux-libs' 'libsecret' 'libappindicator-gtk3' 'libxcrypt-compat' 'electron>=17' 'electron<18')
makedepends=('git' 'nvm' 'jq' 'python')
conflicts=("${pkgname}-bin" "${pkgname}-git")
source=("https://github.com/hovancik/stretchly/archive/v${pkgver}.tar.gz")
sha256sums=('cc01383ef15fe56662cc143e7ac89dd07e10bdd68e963d79229a0643f978b815')
_ensure_local_nvm() {
if type nvm &>/dev/null; then
nvm deactivate
nvm unload
fi
unset npm_config_prefix
export NVM_DIR=${srcdir}/.nvm
. /usr/share/nvm/init-nvm.sh
}
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
_ensure_local_nvm
_node_version=$(jq -r '.engines.node' package.json)
# Don't create an asar package
local TEMP
TEMP=$(mktemp)
jq '.build.asar = false' package.json >"$TEMP"
cp "$TEMP" package.json
rm -f "$TEMP"
# ` || false` is a workaround until this upstream fix is released:
# https://github.com/nvm-sh/nvm/pull/2698
nvm ls "$_node_version" &>/dev/null ||
nvm install "$_node_version" || false
nvm use "$_node_version"
npm install --no-save --no-audit --no-progress --no-fund
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
_ensure_local_nvm
nvm use "$_node_version"
# electron-builder only generates /usr/share/* assets for target package
# types 'apk', 'deb', 'freebsd', 'p5p', 'pacman', 'rpm' and 'sh', so build a
# pacman package and unpack it
local _outfile _appname _electron _unpackdir=${srcdir}/${pkgname}-${pkgver}.unpacked
_outfile=dist/$(jq -r '"\(.name)-\(.version)"' package.json).pacman
_appname=$(jq -r .name package.json)
_electron=${_unpackdir}/opt/${_appname}/${pkgname}
rm -Rf "${_unpackdir}"
mkdir -p "${_unpackdir}"
local i686=ia32 x86_64=x64
./node_modules/.bin/electron-builder build \
--linux pacman \
--"${!CARCH}" \
-c.electronDist=/usr/lib/electron \
-c.electronVersion="$(</usr/lib/electron/version)"
tar -C "${_unpackdir}" -Jxf "${_outfile}"
echo "Deleting Electron ($(du -h "$_electron" | awk '{print $1}'))..." >&2
rm -v "$_electron"
# Replace absolute path in desktop entry
sed -Ei "s/^(Exec=).*/\1stretchly/" \
"${_unpackdir}/usr/share/applications/${pkgname}.desktop"
# Create /usr/bin/stretchly
install -D -m 0755 /dev/null "${_unpackdir}/usr/bin/stretchly"
cat >"${_unpackdir}/usr/bin/stretchly" <<EOF
#!/bin/sh
exec electron '/usr/lib/$(sed -E "s/'/'\\\\''/g" <<<"${_appname}")/' "\$@"
EOF
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
local _appname
_appname=$(jq -r .name package.json)
rm -rf "${pkgdir:?}/usr"
mv "${srcdir}/${pkgname}-${pkgver}.unpacked/usr" "${pkgdir}/"
install -d "${pkgdir}/usr/lib"
mv "${srcdir}/${pkgname}-${pkgver}.unpacked/opt/${_appname}/resources/app" "${pkgdir}/usr/lib/${_appname}"
install -D "${srcdir}/${pkgname}-${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|