blob: 92f794bbc09eb7888e3c7fb8e92096811271f147 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: Luke Arms <luke@arms.to>
pkgname=stretchly-git
_pkgname=${pkgname%-git}
pkgver=872.4df3d0d
pkgrel=1
pkgdesc="The break time reminder app"
arch=('any')
url="https://github.com/hovancik/stretchly/"
license=('BSD')
depends=('c-ares' 'ffmpeg' 'gtk3' 'http-parser' 'libevent' 'libvpx' 'libxslt' 'libxss' 'minizip' 'nss' 're2' 'snappy' 'libnotify' 'libappindicator-gtk3' 'electron')
makedepends=('git' 'nvm' 'jq')
source=("git+https://github.com/hovancik/stretchly.git")
sha256sums=('SKIP')
pkgver() {
cd "${srcdir}/${_pkgname}"
printf '%s.%s' \
"$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "${srcdir}/${_pkgname}"
unset npm_config_prefix
. /usr/share/nvm/init-nvm.sh
_node_version=$(jq -r '.engines.node' package.json)
nvm ls "$_node_version" &>/dev/null || nvm install "$_node_version"
nvm exec "$_node_version" npm install \
electron@"$(cat /usr/lib/electron/version)"
}
build() {
cd "${srcdir}/${_pkgname}"
# electron-builder only generates /usr/share/* assets for target package
# types 'apk', 'deb', 'freebsd', 'p5p', 'pacman', 'rpm' and 'sh', so build a
# pacman package and unpack it
local _unpackdir=${srcdir}/${_pkgname}.unpacked _outfile
rm -Rf "${_unpackdir}"
mkdir -p "${_unpackdir}"
_outfile=dist/$(jq -r '"\(.name)-\(.version)"' package.json).pacman
nvm exec "$_node_version" npx electron-builder build --linux pacman \
-c.electronDist=/usr/lib/electron \
-c.electronVersion="$(cat /usr/lib/electron/version)"
tar -C "${_unpackdir}" -Jxf "${_outfile}"
}
package() {
cd "${srcdir}/${_pkgname}"
local _unpackdir=${srcdir}/${_pkgname}.unpacked _appname
_appname=$(jq -r .name package.json)
# Delete electron binary
rm "${_unpackdir}/opt/${_appname}/${_pkgname}"
# Replace absolute path in desktop entry
sed -Ei "s/^(Exec=).*/\1stretchly/" \
"${_unpackdir}/usr/share/applications/${_pkgname}.desktop"
# Create /usr/bin/stretchly
install -D -m 0755 /dev/null "${_unpackdir}/usr/bin/stretchly"
cat >"${_unpackdir}/usr/bin/stretchly" <<EOF
#!/bin/sh
exec electron /opt/$(printf '%q' "${_appname}")/resources/app.asar "\$@"
EOF
# Move everything into place
mv "${_unpackdir}/"{usr,opt} "${pkgdir}"
install -D -m 0644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|