blob: 99a10f4dccaf9e0f1529783c7b13a83d4ccae8b2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
pkgname=strip-nondeterminism-git
pkgver=0.014.80.9c2df33
pkgrel=1
pkgdesc='Tool for stripping bits of non-deterministic information from files'
url='https://anonscm.debian.org/git/reproducible/strip-nondeterminism.git'
arch=('any')
license=('GPL3')
depends=("perl" 'perl-archive-zip')
makedepends=('git')
options=('!emptydirs')
provides=('strip-nondeterminism')
conflicts=('strip-nondeterminism')
source=(${pkgname}::git+https://anonscm.debian.org/git/reproducible/strip-nondeterminism.git)
sha512sums=('SKIP')
pkgver() {
cd ${pkgname}
printf "%s.%s.%s" "$(git describe --tags --abbrev=0|sed -r 's|(.+/)?(.+)|\2|')" \
"$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd ${pkgname}
sed -r 's|bin/dh_strip_nondeterminism ||g' -i Makefile.PL
}
build() {
cd ${pkgname}
PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
make
}
package() {
cd ${pkgname}
make DESTDIR="${pkgdir}" install
install -Dm 644 README "${pkgdir}/usr/share/doc/${pkgname}/README"
}
# vim: ts=2 sw=2 et:
|