blob: b1f9298cc156d2915fd383ae7aa8a85d4c16876a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: tarball <bootctl@gmail.com>
# Contributor: Giovanni Harting <539@idlegandalf.com>
# Contributor: ny-a <nyaarch64@gmail..com>
# Contributor: Jean Lucas <jean@4ray.co>
# Contributor: Sam Whited <sam@samwhited.com>
pkgname=stripe-cli
pkgver=1.19.3
pkgrel=1
pkgdesc='CLI for Stripe'
arch=(i686 x86_64 aarch64)
url=https://github.com/stripe/stripe-cli
license=(Apache)
depends=(glibc)
makedepends=(go git)
source=($pkgname-$pkgver.tar.gz::https://github.com/stripe/stripe-cli/archive/v$pkgver.tar.gz)
b2sums=('418cb82e1512325954907b2313f5c79d248529190b093a1a706b5ab09c08bf32d2f5167731e5ebe00095a287afe1a9539a0c1987477d68d752745b825c9f72a0')
prepare() {
cd $pkgname-$pkgver
go mod download
}
build() {
cd $pkgname-$pkgver
go generate ./...
go build \
-trimpath \
-buildmode=pie \
-mod=readonly \
-modcacherw \
-ldflags "-linkmode external -X github.com/stripe/stripe-cli/pkg/version.Version=$pkgver -extldflags \"${LDFLAGS}\"" \
-o stripe \
cmd/stripe/main.go
}
check() {
cd $pkgname-$pkgver
[[ "$(./stripe --version)" == "stripe version $pkgver" ]]
# Tests are disabled until https://github.com/stripe/stripe-cli/issues/1020 is resolved
#go test -failfast -race -coverpkg=./... -covermode=atomic -coverprofile=coverage.txt ./... -run . -timeout=2m
}
package() {
cd $pkgname-$pkgver
install -D stripe -t "$pkgdir"/usr/bin
install -Dm644 README.md -t "$pkgdir"/usr/share/doc/$pkgname
cp -a docs "$pkgdir"/usr/share/doc/$pkgname
}
|