PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Daniel Hillenbrand <codeworkx at bbqlinux dot org>

_pkgbase=stubby
pkgname=stubby-git
pkgver=2543.81bfa684
pkgrel=1
pkgdesc="DNS Privacy Daemon"
arch=('x86_64' 'i686')
url="https://dnsprivacy.org/wiki/display/DP/DNS+Privacy+Daemon+-+Stubby"
license=('BSD')

makedepends=('libtool' 'git')
depends=('libyaml' 'openssl')

source=("$_pkgbase::git+https://github.com/getdnsapi/getdns.git")
sha256sums=('SKIP')

backup=('usr/etc/stubby/stubby.yml')
install=install

pkgver() {
  cd "$srcdir/$_pkgbase"
  printf "%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$srcdir/$_pkgbase"
  git submodule update --init
  libtoolize -ci
  autoreconf -fi
  ./configure --prefix=/usr --without-libidn --enable-stub-only --with-ssl=/usr --with-stubby
}

build() {
  cd "$srcdir/$_pkgbase"
  make
}

package() {
  cd "$srcdir/$_pkgbase"
  make DESTDIR="${pkgdir}" install

  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/$_pkgbase/LICENSE"

  install -D -m644 stubby/systemd/stubby.service "${pkgdir}/usr/lib/systemd/system/stubby.service"
  install -D -m644 stubby/systemd/stubby.conf "${pkgdir}/usr/lib/tmpfiles.d/stubby.conf"
}