blob: 7eaea48f77dc805d7dd82bc7ec5abd455ce8fe32 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: txtsd <aur.archlinux@ihavea.quest>
pkgname=stump
pkgver=0.1.3
pkgrel=1
pkgdesc='A free and open source comics, manga and digital book server with OPDS support'
arch=(x86_64)
url='https://github.com/stumpapp/stump'
license=('MIT')
depends=(
gcc-libs
glibc
)
makedepends=(
cargo
npm
yarn
)
checkdepends=()
optdepends=()
backup=()
options=(!lto)
source=(
"${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz"
"${pkgname}.service"
"${pkgname}.sysusers"
"${pkgname}.tmpfiles"
)
sha256sums=('ca63bc291f4ba661a8ee6ca2dc63aca87412ca98d56d610a03280650bd5fc5bb'
'0acbaeaeec495b4ae9e55401edb4d1f395fb3b2edc68d8c41f0d9fffe925f0ea'
'da29676564e82d6b642b433156e679055d776c790f61356b64a0a5d65be476ef'
'366d457de40ce59aa50fe860a21b8db2db84a8fd48fc2a68f38b0eff2ec73dcc')
prepare() {
cd "${pkgname}-${pkgver}"
yarn install --frozen-lockfile
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "${pkgname}-${pkgver}"
export CARGO_TARGET_DIR=target
export GIT_REV=681b131
yarn web build
# cargo build --package prisma-cli --bin prisma-cli --frozen --release
# target/release/prisma-cli generate --schema=./core/prisma/schema.prisma
cargo build --package stump_server --bin stump_server --frozen --release
}
package() {
cd "${pkgname}-${pkgver}"
install -Dm755 "target/release/stump_server" "${pkgdir}/usr/bin/stump_server"
install -dm755 "${pkgdir}/usr/share/${pkgname}"
cp -r "apps/web/dist" "${pkgdir}/usr/share/${pkgname}/"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
cd "${srcdir}"
install -Dm644 stump.service "${pkgdir}/usr/lib/systemd/system/stump.service"
install -Dm644 stump.sysusers "${pkgdir}/usr/lib/sysusers.d/stump.conf"
install -Dm644 stump.tmpfiles "${pkgdir}/usr/lib/tmpfiles.d/stump.conf"
}
|