summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: b2196fc52113b276a28882fe5d68a751fdb3f9da (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
# Contributor: Chris Dunder <echo Y2R1bmRlckBnbWFpbC5jb20K | base64 -d>
# Contributor: M Rawash <mrawash@gmail.com>
# Contributor: olvar <beren dot olvar (at) gmail dot com>
# Contributor: Andrew Antle <andrew dot antle at gmail dot com>
# Contributor: joyfulgirl <joyfulgirl (at) archlinux.us>
# Contributor: Jonathan Friedman <jonf@gojon.com>
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>

pkgname=stumpwm-git
_pkgname=stumpwm
pkgver=18.05.94.g2ede972
pkgrel=1
pkgdesc="A tiling, keyboard-driven window manager written in common lisp"
arch=('i686' 'x86_64')
url="https://stumpwm.github.io"
license=('GPL2')
conflicts=('stumpwm' 'stumpwm-contrib')
provides=('stumpwm' 'stumpwm-contrib')

source=(${_pkgname}::git+https://github.com/stumpwm/stumpwm stumpwm.desktop
        ${_pkgname}-contrib-git::git+https://github.com/stumpwm/stumpwm-contrib)
md5sums=('SKIP'
         'b5721de9b1cbdb4548d11570a512c5d4'
         'SKIP')

makedepends=('common-lisp' 'cl-asdf' 'clx-git' 'cl-ppcre' 'cl-alexandria')
optdepends=('xorg-xprop: for stumpish (StumpWM Interactive Shell)'
            'rlwrap: for stumpish completion and history'
            'emacs: Edit and eval stumpwm code with M-x stumpwm-mode'
            'alsa-utils: for amixer.lisp (control audio volume)'
            'aumix: for aumix.lisp (control audio volume)'
            'mpd: for mpd.lisp (control the mpd)'
            'surfraw: for surfraw.lisp (surf the Internet)'
            'clx-truetype: for ttf-fonts.lisp (Xft fonts)')

# Binary will not run other
options=('!strip' '!makeflags')  # Thanks to sidereus for pointing this out

pkgver() {
  cd ${_pkgname}
  git describe --long --tags|tr - .
}

_contribdest=/usr/share/stumpwm/contrib

build() {
  cd ${_pkgname}

  autoconf
  ./configure --prefix=/usr --with-module-dir=${_contribdest}
  make
} 

package() {
  cd ${_pkgname}

  make destdir="$pkgdir/" install

  install -Dm 644 sample-stumpwmrc.lisp \
	  ${pkgdir}/usr/share/${_pkgname}/stumpwmrc.sample

  # contrib modules
  install -d "$pkgdir"/${_contribdest}
  cp -dr --no-preserve=ownership ${srcdir}/${_pkgname}-contrib-git/* \
     ${pkgdir}${_contribdest}

  # stumpish
  install -Dm755 "$pkgdir"/${_contribdest}/util/stumpish/stumpish \
	  "$pkgdir"/usr/bin/stumpish

  rm -rf "$pkgdir"/${_contribdest}/util/stumpish

  # emacs mode
  cd "$pkgdir"/${_contribdest}/util/swm-emacs
  install -d "$pkgdir"/usr/share/emacs/site-lisp/
  for _i in *.el 
  do
    install -Dm644 ${_i} "$pkgdir"/usr/share/emacs/site-lisp/${_i}
  done
  install -Dm644 "$srcdir"/stumpwm.desktop "$pkgdir"/usr/share/xsessions/stumpwm.desktop
}