PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

# Maintainer: Bian Jiaping <ssbianjp@gmail.com>
# Contributor: Randy Ramos <rramos1295 \at\ gmail \dot\ com>
# Contributor: carstene1ns <arch carsten-teibes de>
# Contributor: DonOregano <lars@foldspace.nu>

pkgname=subgit
pkgver=3.3.17
pkgrel=1
pkgdesc="Provides smooth Subversion to Git migration and bidirectional synchronization"
arch=('any')
url="https://subgit.com"
license=('custom')
depends=('java-runtime-headless>=8')
optdepends=('subversion' 'git')
source=("https://subgit.com/files/subgit-${pkgver}.zip")
md5sums=('b37b889990eb15177ccd8a1afd11eda4')

package() {
  cd subgit-$pkgver

  # folders
  install -d "$pkgdir"/usr/{bin,share/{{licenses,doc}/subgit,subgit/lib}}
  # script
  install -Dm755 bin/subgit "$pkgdir"/usr/share/subgit/bin/subgit
  # libs
  install -Dm644 lib/*.jar "$pkgdir"/usr/share/subgit/lib
  # doc
  install -Dm644 {CHANGES,README}.txt "$pkgdir"/usr/share/doc/subgit
  # licenses
  install -Dm644 LICENSE.txt lib/licenses/*.txt "$pkgdir"/usr/share/licenses/subgit
  # symlink to make command available
  ln -s /usr/share/subgit/bin/subgit "$pkgdir"/usr/bin/subgit
}