blob: e53c8fe44b131fb3be576e9c7cc435037ee6f4ab (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: tuxxx <nzb_tuxxx@proton.me>
pkgbase=subtitles-contact-sheet-qt
pkgname=(
subtitles-contact-sheet-qt-cli
subtitles-contact-sheet-qt-gui
)
_pkgname=subtitles_contact_sheet_qt
pkgver=1.18
pkgrel=1
pkgdesc="Create subtitles/video contact sheets, previews, small animations, screenshots and thumbnails"
arch=('x86_64')
url='https://vongoob9.gitlab.io/subtitles_contact_sheet_qt'
license=('GPL-3.0-or-later')
depends=('qt6-base' 'ffmpeg')
makedepends=('pandoc-cli')
optdepends=('ttf-dejavu: default font for scs')
conflicts=('subtitles-contact-sheet-qt-cli-git' 'subtitles-contact-sheet-qt-gui-git')
source=("${_pkgname}-${pkgver}.tar.gz::https://gitlab.com/vongooB9/${_pkgname}/-/archive/${pkgver}/${_pkgname}-${pkgver}.tar.gz")
b2sums=('142968109b340478cadadb2b8ff14d8d0ccf867afa59ef2d7ed3335883bd8715fe1612ab4e5078ba753c6c216f50e2fc0964fbb971c7637d104687f1df9f0c65')
build() {
cd "${srcdir}/${_pkgname}-${pkgver}"
qmake6 USR_DIR=/usr MAN_DIR=/share/man/man1
make
( cd SCSGUI && qmake6 USR_DIR=/usr ICONS_DIR=/share/icons/hicolor/scalable/apps && make )
}
package_subtitles-contact-sheet-qt-cli() {
pkgdesc+=' (CLI)'
cd "${srcdir}/${_pkgname}-${pkgver}"
make INSTALL_ROOT="${pkgdir}" install
}
package_subtitles-contact-sheet-qt-gui() {
pkgdesc+=' (Qt GUI)'
depends+=('subtitles-contact-sheet-qt-cli')
cd "${srcdir}/${_pkgname}-${pkgver}/SCSGUI"
make INSTALL_ROOT="${pkgdir}" install
}
|