blob: 94017388a084e75908a595f5c7787a9856b7dbe6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
|
# Maintainer: orhun <orhunparmaksiz@gmail.com>
# Maintainer: Skallwar <estblcsk@gmail.com>
# https://github.com/orhun/pkgbuilds
pkgname=suckit
pkgver=0.1.0
pkgrel=1
pkgdesc="Recursively visit and download a website's content to your disk"
arch=('x86_64')
url="https://github.com/Skallwar/suckit"
license=('Apache')
makedepends=('rust')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('8ab90817a780bb69c060482fce9c9e501eac8ff8e73cff4b964e08334a5ce506ef08c0f23c3811b15db314a5e9c6f3711326646d993602e31344bac11f31fdf3')
build() {
cd "$pkgname-$pkgver"
cargo build --release --locked --all-features
}
check() {
cd "$pkgname-$pkgver"
# TODO: add `--release` flag after new release
# https://github.com/Skallwar/suckit/commit/d9c17d9ec2459732ca0dee7b057002ecf7efd04a
cargo test --locked --all-features
}
package() {
cd "$pkgname-$pkgver"
install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
}
|