PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75

# Maintainer: Sebastian Tobie <archlinux@sebastian-tobie.de>
# Contributor: Patrick Northon <northon_patrick3@yahoo.ca>
# based on the PKGBUILD of sulis

pkgname=sulis-git
pkgver=1.0.0.20230718
pkgrel=2
pkgdesc='Turn based tactical RPG with several campaigns, written in Rust.'
arch=('x86_64')
url='https://www.sulisgame.com/'
license=('GPL3')
depends=(
    'alsa-lib'
    'freetype2'
    'fontconfig'
    'gcc-libs'
    'glibc'
    'zlib'
    'bzip2'
    'libpng'
    'harfbuzz'
    'brotli'
    'expat'
    'glib2'
    'graphite'
    'brotli'
    'pcre2'
)
makedepends=('rust' 'cargo' 'gendesk')
source=(
	"sulis::git+https://github.com/Grokmoo/sulis.git"
	'sulis.png'
)
sha256sums=(
	'SKIP'
	'7bffe4886ea6dc139135790f8711611a1cccdc8d3b318ae18ff3227e915c604d'
)
options=('!lto')
conflicts=(
    'sulis'
    'sulis-bin'
)

pkgver() {
	cd sulis
	git log -1 HEAD --format='%(describe:tags,abbrev=0).%cs' |  sed 's/\([^-]*-g\)/r\1/;s/-//g'
}

prepare() {
    gendesk -f -n --pkgname "sulis" --name "Sulis" --pkgdesc "${pkgdesc}s" --exec="/opt/sulis/sulis" --categories=Game --icon sulis --path=/opt/sulis
    gendesk -f -n --pkgname "sulis-editor" --name 'Sulis Editor' --pkgdesc "${pkgdesc}s" --exec="/opt/sulis/sulis-editor" --categories=Game --icon sulis --path=/opt/sulis
}

build() {
	_srcdir="$PWD"
	cd "sulis"
	RUSTUP_TOOLCHAIN=stable cargo build --release --workspace --locked --all-features --target-dir="${_srcdir}/target"
}

package() {
	install -Dm755 'target/release/main' -T "${pkgdir}/opt/sulis/sulis"
	install -Dm755 'target/release/editor' -T "${pkgdir}/opt/sulis/editor"
	
	install -Dm644 'sulis.desktop' -t "${pkgdir}/usr/share/applications"
	install -Dm644 'sulis-editor.desktop' -t "${pkgdir}/usr/share/applications"
	install -Dm644 'sulis.png' -t "${pkgdir}/usr/share/pixmaps"

	cd "sulis"
	install -Dm644 'config.sample.yml' -t "${pkgdir}/opt/sulis"
	cp -r 'data' "${pkgdir}/opt/sulis/"
	cp -r 'campaigns' "${pkgdir}/opt/sulis/"
	cp -r 'mods' "${pkgdir}/opt/sulis/"
	
	install -Dm644 'docs/GPLv3-LICENSE' "${pkgdir}/usr/share/licenses/sulis/LICENSE"
}