blob: a545df3ee0bbcb882f4e8e657d9c7ac980955e65 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: Aleksandar Trifunović <akstrfn at gmail dot com>
# Contributor: Holger Doebler <holger DOD doebler AD posteo DOD de>
# Contributor: Florian Jacob <projects+arch AT florianjacob )DOT( de>
# Contributor: mareex <marcus [dot] behrendt [dot] 86 [at] gmail [dot] com>
pkgname=('sumo' 'sumo-doc')
pkgbase=sumo
pkgver=1.19.0
pkgrel=3
pkgdesc="Traffic simulation modelling road vehicles, public transport and pedestrians."
arch=('i686' 'x86_64')
url="http://sumo.dlr.de"
license=('EPL-2.0')
depends=('openscenegraph' 'proj' 'fox' 'xerces-c' 'gdal' 'gl2ps' 'flake8' 'autopep8' 'python-pyproj' 'python-pandas' 'python-scipy' 'ffmpeg' 'python-matplotlib')
makedepends=('cmake' 'help2man' 'swig' 'gtest' 'gmock' 'python-setuptools' 'python-build' 'eigen' 'jdk-openjdk' 'maven' 'git' 'python-pip')
source=("https://sumo.dlr.de/releases/${pkgver}/sumo-src-${pkgver}.tar.gz")
sha256sums=('7643b1f8a3d7144f181542c9c7b8c72f3e8e45ba9c627912665083db0fe106cd')
prepare() {
# workaround for invalid version string generated by sumo at v1.19
sed -i "42i\ return 'v1_19_00'" "$pkgname-$pkgver"/tools/build/version.py
cmake -B build -S "$pkgname-$pkgver" \
-DCMAKE_INSTALL_LIBDIR=lib \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release
}
build() {
cmake --build build
cmake --build build -- man
}
# example tests still fails
# check() {
# cd ${pkgbase}-${pkgver}
# cmake --build build -- test
# }
package_sumo() {
optdepends=('java-runtime-common: for executing Jar files like TraCI4J')
# Installs just the bin files
cmake --build build -- DESTDIR="${pkgdir}/" install
cd ${pkgbase}-${pkgver}
install -Dm644 data/logo/sumo-128x138.png ${pkgdir}/usr/share/pixmaps/${pkgbase}.png
install -Dm644 build/package/${pkgbase}.desktop -t ${pkgdir}/usr/share/applications/
install -Dm644 build/package/*sh -t ${pkgdir}/etc/profile.d/
}
package_sumo-doc() {
cd ${pkgbase}-${pkgver}
install -d ${pkgdir}/usr/share/doc/${pkgbase}
# just man pages for now
# cp -a * ${pkgdir}/usr/share/doc/${pkgbase}/
install -Dm644 docs/man/* -t ${pkgdir}/usr/share/man/man1/
install -m0644 {AUTHORS,ChangeLog,LICENSE,README.md} ${pkgdir}/usr/share/doc/${pkgbase}
}
|