blob: 3b39c0356e79a1c956f9f518e560eebdb7bd245d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Oscar Tienda <contacto@oscartienda.com>
pkgname=sunsync
pkgver=0.2.3
pkgrel=1
pkgdesc="Import games from Lutris, Steam, Heroic and other launchers into Sunshine (KDE Plasma Wayland)"
arch=('any')
url="https://github.com/OscarTienda/SunSync"
license=('MIT')
depends=(
'python'
'python-pyqt6'
'python-requests'
'python-pillow'
)
optdepends=(
'krfb: virtual monitor support (krfb-virtualmonitor)'
'libkscreen: virtual display mode switching (kscreen-doctor)'
'qt6-tools: virtual display helpers (qdbus6)'
)
makedepends=(
'python-build'
'python-installer'
'python-wheel'
'python-hatchling'
)
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('17253621743dcfbe9822e14cf1ddee9d9e9d251292e7a816a1c721a7491a03dc')
build() {
cd "$srcdir/SunSync-$pkgver"
python -m build --wheel --no-isolation
}
package() {
cd "$srcdir/SunSync-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 assets/sunsync.desktop "$pkgdir/usr/share/applications/sunsync.desktop"
install -Dm644 assets/sunsync.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/sunsync.svg"
# Virtual-monitor scripts, also discoverable at /usr/share/sunsync/scripts.
install -Dm755 scripts/sunshine-start-vmon.sh "$pkgdir/usr/share/sunsync/scripts/sunshine-start-vmon.sh"
install -Dm755 scripts/sunshine-stop-vmon.sh "$pkgdir/usr/share/sunsync/scripts/sunshine-stop-vmon.sh"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|