blob: fa5e09bd565a5be3b2bf57a4f3ac90e998a6a244 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: Lukas1818 aur at lukas1818 dot de
pkgname=superslicer
pkgver=2.2.54.2
_pkgtag=$pkgver
pkgrel=3
pkgdesc="G-code generator for 3D printers (RepRap, Makerbot, Ultimaker etc.)"
arch=('x86_64')
url="https://github.com/supermerill/SuperSlicer"
license=('AGPL3')
depends=('cgal' 'glew' 'nlopt' 'openvdb' 'wxgtk3-dev-opt' 'boost>=1.73.0' 'qhull>=2020.2-4')
replaces=('slic3r++')
makedepends=('cereal' 'cmake' 'eigen' 'libigl' 'openvdb' 'wxgtk2-dev-opt') # cmake doesn't detect wx if not both gtk2 and gtk3 are installed
source=("https://github.com/supermerill//SuperSlicer/archive/$_pkgtag.tar.gz"
"superslicer.desktop"
"start-superslicer.sh"
"0001-wxgtk3-is-broken-on-wayland.patch"
"0001-Replace-deprecated-Boost-header-in-admesh.patch")
sha512sums=('3e28d28f463be49217d4aa19691bd190d644f86474786db69ec82d58090d2231a6c0add66eec59ac9f8c2169bfcd730a0c9deafd9df48182e92194bf6d2f39b6'
'8f75de56ba3e29b9c650d2946bd11afcf406a7fd42d2620ec44e4e76f6b64626de720190ce0f8be29ba7c48f714bfa0a71c45f868bdce7bc1ac7dbbc0e9e7583'
'abfbd056be518b1b733cddef6c430cc3c4199d5df13067574dd3269cf35b798e11b43f55f1dfb57d6d8ee1da06882825fef0f7a170a9b069b95e9aea1ec8f31d'
'acf35ebe467e9fb30f1b77d15348f1a7b82dcf45a5b829e375e972b5d6b49968603b3fa090c4d1f56e8b5148e2b820e79afa269da60ace70de1ceadcf6e820c5'
'9a860dbac69ca7a195ef43cb2b80a8b5cf2c34bddb91867aa8ba16bbb754ab68c4baf57fa7e2562f96facc435c64ed8445505edb152382dbc5106a509136a2c8')
prepare()
{
cd "$srcdir/SuperSlicer-$_pkgtag"
# disabling tests is not enough, we need to remove them explicitly
sed -i 's,add_subdirectory(test),,g' src/CMakeLists.txt
# apply patches
patch --forward --strip=1 --input="$srcdir/0001-wxgtk3-is-broken-on-wayland.patch"
patch --forward --strip=1 --input="$srcdir/0001-Replace-deprecated-Boost-header-in-admesh.patch"
}
build()
{
cd "$srcdir/SuperSlicer-$_pkgtag"
mkdir -p build
cd build
cmake .. \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DOpenGL_GL_PREFERENCE=GLVND \
-DSLIC3R_FHS=ON \
-DSLIC3R_STATIC=OFF \
-DSLIC3R_WX_STABLE=ON \
-DSLIC3R_GTK=3 \
-DSLIC3R_BUILD_TESTS=OFF \
-DwxWidgets_CONFIG_EXECUTABLE=/opt/wxgtk-dev/bin/wx-config
make
}
package()
{
cd "$srcdir/SuperSlicer-$_pkgtag/build"
make DESTDIR="$pkgdir" install
test ! -h "$pkgdir/usr/share/SuperSlicer/resources" || rm "$pkgdir/usr/share/SuperSlicer/resources"
install -d "$pkgdir/usr/share/applications"
install -m 644 "$srcdir/superslicer.desktop" "$pkgdir/usr/share/applications/"
mv "$pkgdir/usr/bin/superslicer" "$pkgdir/usr/share/SuperSlicer"
install -Dm 755 "${srcdir}/start-superslicer.sh" "${pkgdir}/usr/bin/superslicer"
}
|