PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69

# Maintainer: Tulpenkiste <tulpenkiste at the amogus email domain which is .cloud>
# Contributor: Frederic Bezies <fredbezies at gmail dot com>
# Contributor: Xiao-Long Chen <chenxiaolong@cxl.epac.to>
# Original Maintainer: Hakim <acrox999 at gmail dot com>
# Contributor: Patrick Bartels <p4ddy.b@gmail.com>

_pkgname=supertux
pkgname=supertux-git

pkgver=0.6.3.r1599.g6f1078d10
pkgrel=1

pkgdesc="A classic 2D jump'n run sidescroller game in a style similar to the original SuperMario game"
url='https://www.supertux.org'

license=(GPL-3.0-only)
arch=('x86_64' 'riscv64' 'aarch64' 'i686' 'riscv32' 'armv7h')

depends=('sdl2_image' 'openal' 'libvorbis' 'glew' 'boost-libs' 'curl' 'physfs' 'hicolor-icon-theme' 'libraqm' 'squirrel')
makedepends=('git' 'cmake' 'boost' 'glm')
optdepends=(
	'discord: Discord Rich Presence integration'
	'arrpc: Unofficial Discord client Rich Presence integration'
)

conflicts=(supertux)
provides=(supertux)

source=('git+https://github.com/SuperTux/supertux.git')
sha512sums=('SKIP')
options=(!debug)

pkgver() {
	cd "$_pkgname"
	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g' | cut -c2-48
}

prepare() {
	cd "$_pkgname"

	git submodule update --init --recursive

	#sed -i '/curl\/types.h/d' src/addon/addon_manager.cpp
	#sed -i '1i#include <cstddef>' src/supertux/screen_manager.hpp
}

build() {
	cd "$_pkgname"

	export CFLAGS+=" -fPIC"
	export CXXFLAGS+=" -fPIC"

	cmake -B build \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DCMAKE_BUILD_TYPE=RelWithDebInfo \
		-DINSTALL_SUBDIR_BIN=bin -DINSTALL_SUBDIR_SHARE=share/supertux2 \
		-DSSQ_USE_SQ_SUBMODULE=OFF \
		-DENABLE_DISCORD=On

	cmake --build build
}

package() {
	cd "$_pkgname"

	mkdir "${pkgdir}/usr"

	cmake --install build --prefix "${pkgdir}/usr"
}