summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 4f43f948a7a01b8ce3be7fd7d55c0f669c24f1e2 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
# Maintainer: Frederic Bezies <fredbezies at gmail dot com>
# Contributor: Xiao-Long Chen <chenxiaolong@cxl.epac.to>
# Original Maintainer: Hakim <acrox999 at gmail dot com>
# Contributor: Patrick Bartels <p4ddy.b@gmail.com>

pkgname=supertux-git
_pkgname=supertux
pkgver=v0.5.1.r489.gd3ddd5a34
pkgrel=1
epoch=1
pkgdesc="A classic 2D jump'n run sidescroller game in a style similar to the original SuperMario game"
url='http://supertux.lethargik.org/'
license=(GPL)
arch=(i686 x86_64)
depends=('sdl2_image' 'openal' 'libvorbis' 'glew' 'boost-libs' 'curl')
makedepends=('git' 'cmake' 'physfs' 'boost')
conflicts=(supertux)
provides=(supertux)
source=('git+https://github.com/SuperTux/supertux.git')
sha512sums=('SKIP')
           
pkgver() {
  cd "$_pkgname"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "$_pkgname"

  git submodule update --init --recursive

  sed -i '/curl\/types.h/d' src/addon/addon_manager.cpp
  sed -i '1i#include <cstddef>' src/supertux/screen_manager.hpp  
}

build() {
  cd "$_pkgname"

  export CFLAGS+=" -fPIC"
  export CXXFLAGS+=" -fPIC"

  cmake . \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=RelWithDebInfo \
    -DINSTALL_SUBDIR_BIN=bin

  make
}

package() {
  cd "$_pkgname"

  make DESTDIR="${pkgdir}/" install
}