blob: d4f998ba1a7c46141904da8d2e89d2f70329f3de (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: xiota / aur.chaotic.cx
# Contributor: Pellegrino Prevete <pellegrinoprevete@gmail.com>
# Contributor: Kevin Majewski <kevin.majewski02@gmail.com>
_pkgname="sushi"
pkgname="$_pkgname-git"
pkgver=46.0.r1.g819642a
pkgrel=1
pkgdesc="A quick previewer for Nautilus"
url="https://gitlab.gnome.org/GNOME/sushi"
license=('GPL-2.0-or-later')
arch=('x86_64')
depends=(
'evince'
'gjs'
'gst-plugins-base-libs'
'gtksourceview4'
'libsoup3'
'webkit2gtk-4.1'
)
makedepends=(
'git'
'gobject-introspection'
'meson'
)
optdepends=(
'libreoffice: OpenDocument formats'
)
provides=("$_pkgname=${pkgver%%.r*}")
conflicts=("$_pkgname")
_pkgsrc="$_pkgname"
source=("$_pkgsrc"::"git+$url.git")
sha256sums=('SKIP')
pkgver() {
cd "$_pkgsrc"
git describe --long --tags --abbrev=7 --exclude='*[a-zA-Z][a-zA-Z]*' \
| sed -E 's/^v//;s/([^-]*-g)/r\1/;s/-/./g'
}
build() {
arch-meson "$_pkgsrc" build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
meson install -C build --destdir "$pkgdir"
}
|