PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Maintainer: zxp19821005 <zxp19821005 at 163 dot com>
_officalname=suwell-reader
pkgname="${_officalname}-bin"
_pkgname=SuwellReader
_appname="cn.${_officalname//-/.}"
pkgver=3.0.22.0916
pkgrel=9
pkgdesc="OFD Reader Professional 3.0 From Suwell .LTD. Prebuilt version."
provides=("${pkgname%-bin}")
conflicts=("${pkgname%-bin}")
arch=('x86_64')
url="https://www.suwell.cn/"
_downurl="https://com-store-packages.uniontech.com"
license=('LicenseRef-custom')
depends=(
    'gtk2'
    'libpng12'
    'glu'
    'libjpeg6-turbo'
    'gstreamer'
    'libice'
    'libxt'
    'libsm'
)
options=(
    '!strip'
    '!emptydirs'
)
source=(
    "${pkgname%-bin}-${pkgver}.deb::${_downurl}/appstore/pool/appstore/c/${_appname}.appstore/${_appname}.appstore_${pkgver}-1_amd64.deb"
    "${pkgname%-bin}.sh"
)
sha256sums=('69e56165f999ca8a168d64d0e22180755c67091b700fca1e339910580b127d1f'
            '2144461f37fe70f8ba576fbcf33ba7cc8179d133295a58519aa51c0ff5a48d2b')
build() {
    sed -e "
        s/@appname@/${pkgname%-bin}/g
        s/@runname@/${_pkgname}/g
    " -i "${srcdir}/${pkgname%-bin}.sh"
    bsdtar -xf "${srcdir}/data."*
    sed -e "
        s/\/usr\/bin\/${_officalname//-/}/${pkgname%-bin}/g
        /serverice/d
        /^#/d
        s/\/opt\/apps\/${_appname}\/entries\/icons\/hicolor\/256x256\/mimetypes\/${_appname}.app-x-${_officalname//-/}.png/${pkgname%-bin}/g
    " -i "${srcdir}/usr/share/applications/${_appname}.desktop"
}
package() {
    install -Dm755 "${srcdir}/${pkgname%-bin}.sh" "${pkgdir}/usr/bin/${pkgname%-bin}"
    install -Dm755 -d "${pkgdir}/usr/lib/${pkgname%-bin}"
    cp -Pr --no-preserve=ownership "${srcdir}/opt/apps/${_appname}/files/bin/suwell/"* "${pkgdir}/usr/lib/${pkgname%-bin}"
    install -Dm644 "${srcdir}/usr/share/applications/${_appname}.desktop" "${pkgdir}/usr/share/applications/${pkgname%-bin}.desktop"
    install -Dm644 "${srcdir}/usr/share/fonts/cesi_font/"*.ttf -t "${pkgdir}/usr/share/fonts/cesi-font"
    install -Dm644 "${srcdir}/usr/share/mime/packages/"*.xml -t "${pkgdir}/usr/share/mime/packages"
    for _icons in 16x16 24x24 32x32 64x64 96x96 128x128 256x256 512x512;do
        install -Dm644 "${srcdir}/usr/share/icons/hicolor/${_icons}/apps/${_appname}.app-x-suwellreader.png" \
            "${pkgdir}/usr/share/icons/hicolor/${_icons}/apps/${pkgname%-bin}.png"
    done
}