summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 03e86bfcade3823271f2a8fa08ef63a270647fcc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
# Maintainer: Christian Hesse <mail@eworm.de>

pkgname=svkbd-git
pkgver=0.r50.gfc26700
pkgrel=1
pkgdesc='simple virtual keyboard - git checkout'
arch=('i686' 'x86_64')
url='http://tools.suckless.org/x/svkbd'
depends=('libx11' 'libxtst')
conflicts=('svkbd')
provides=('svkbd')
makedepends=('git' 'markdown')
license=('MIT')
source=('git://git.suckless.org/svkbd')
sha256sums=('SKIP')

pkgver() {
	cd svkbd/

	if GITTAG="$(git describe --abbrev=0 --tags 2>/dev/null)"; then
		printf '%s.r%s.g%s' \
			"$(sed -e "s/^${pkgname%%-git}//" -e 's/^[-_/a-zA-Z]\+//' -e 's/[-_+]/./g' <<< ${GITTAG})" \
			"$(git rev-list --count ${GITTAG}..)" \
			"$(git log -1 --format='%h')"
	else
		printf '0.r%s.g%s' \
			"$(git rev-list --count master)" \
			"$(git log -1 --format='%h')"
	fi
}

build() {
	cd svkbd/

	make

	markdown README.md > README.html
}

package() {
	cd svkbd/

	make DESTDIR="${pkgdir}" PREFIX='/usr/' install

	install -D -m0644 'LICENSE' "${pkgdir}/usr/share/licenses/vis/LICENSE"
	install -D -m0644 'README.md' "${pkgdir}/usr/share/doc/vis/README.md"
	install -D -m0644 'README.html' "${pkgdir}/usr/share/doc/vis/README.html"
}