blob: f5da2558b536dd977f10bd41743091f93b3af14a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: CWZMorro <cwzmorro@gmail.com>
pkgname=swap-os-git
_pkgname=swap-OS
pkgver=2.0.0.r14.g0d80eaa
pkgrel=1
pkgdesc="A tool to enable seemless swap between different OS"
arch=('any')
url="https://github.com/CWZMorro/swap-OS"
license=('MIT')
depends=('jq' 'lsof' 'util-linux' 'systemd')
optdepends=('grub: for GRUB bootloader support')
makedepends=('git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("git+https://github.com/CWZMorro/swap-OS.git")
sha256sums=('SKIP')
backup=('etc/swapos.conf')
pkgver() {
cd "$_pkgname"
if git describe --long --tags >/dev/null 2>&1; then
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
else
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
fi
}
package() {
cd "$_pkgname"
make install DESTDIR="$pkgdir" PREFIX=/usr
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|