blob: de22fc5557d808331589c336fb1afa43515aabd3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: novenary <streetwalkermc@gmail.com>
# Contributor: Brett Cornwall <ainola@archlinux.org>
# Contributor: Maxim Baz <$pkgname at maximbaz dot com>
# Contributor: Alexander F. Rødseth <xyproto@archlinux.org>
pkgname=sway9
pkgver=1.7
epoch=1
pkgrel=1
_commit=8afad182dffe7b4dc68481a1fcb301e427c8b536
pkgdesc='Tiling Wayland compositor and replacement for the i3 window manager (personal build)'
arch=(x86_64)
url='https://github.com/9ary/sway9'
license=(MIT)
depends=(
'cairo'
'gdk-pixbuf2'
'json-c'
'pango'
'polkit'
'pcre'
'swaybg'
'ttf-font'
'wlroots'
)
makedepends=(git meson ninja scdoc setconf wayland-protocols)
provides=(sway)
conflicts=(sway)
backup=(etc/sway/config)
optdepends=(
'dmenu: Application launcher'
'grim: Screenshot utility'
'i3status: Status line'
'mako: Lightweight notification daemon'
'slurp: Select a region'
'swayidle: Idle management daemon'
'swaylock: Screen locker'
'wallutils: Timed wallpapers'
'waybar: Highly customizable bar'
'xorg-xwayland: X11 support'
)
source=("git+https://github.com/9ary/$pkgname.git#commit=$_commit"
"50-systemd-user.conf")
sha512sums=('SKIP'
'c2b7d808f4231f318e03789015624fd4cf32b81434b15406570b4e144c0defc54e216d881447e6fd9fc18d7da608cccb61c32e0e1fab2f1fe2750acf812d3137')
build() {
mkdir -p build
arch-meson build "$pkgname" -D sd-bus-provider=libsystemd -D werror=false -D b_ndebug=true
ninja -C build
}
package() {
DESTDIR="$pkgdir" ninja -C build install
install -Dm644 "$pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm644 50-systemd-user.conf -t "$pkgdir/etc/sway/config.d/"
for util in autoname-workspaces.py inactive-windows-transparency.py grimshot; do
install -Dm755 "$pkgname/contrib/$util" -t \
"$pkgdir/usr/share/$pkgname/scripts"
done
}
# vim: ts=2 sw=2 et
|