PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

# Maintainer: Tuwum <tuwum@wairu.space>
pkgname="swayfx-elogind"
pkgver=0.5.3
pkgrel=4
license=("MIT")
pkgdesc="SwayFX: Sway, but with eye candy!"
makedepends=(
        "git"
        "meson"
        "scdoc"
        "wayland-protocols"
)
depends=(
        "cairo"
        "gdk-pixbuf2"
        "libevdev.so"
        "libinput"
        "libjson-c.so"
        "libudev.so"
        "libwayland-server.so"
        "libxcb"
        "libxkbcommon.so"
        "pango"
        "pcre2"
        "scenefx0.4"
        "ttf-font"
        "wlroots0.19"
)
optdepends=(
        "brightnessctl: Brightness adjustment tool used in the default configuration"
        "foot: Terminal emulator used in the default configuration"
        "i3status: Status line generation"
        "libpulse: Volume adjustment tool (pactl) used in the default configuration"
        "mako: Lightweight notification daemon"
        "polkit: System privilege control. Required if not using seatd service"
        "swaybg: Wallpaper tool for sway"
        "sway-contrib: Collection of user-contributed scripts for sway"
        "swayidle: Idle management daemon"
        "swaylock: Screen locker"
        "wmenu: Application launcher used in default config"
        "xorg-xwayland: X11 support"
        "xdg-desktop-portal-gtk: Default xdg-desktop-portal for file picking"
        "xdg-desktop-portal-wlr: xdg-desktop-portal backend"
)
backup=(etc/sway/config)
arch=("i686" "x86_64")
url="https://github.com/WillPower3309/swayfx"
source=("swayfx-${pkgver}.tar.gz::${url}/archive/refs/tags/$pkgver.tar.gz"
        sway-portals.conf)
sha512sums=(
        "SKIP"
        "790741df028822bf4d83170dea57e1c63f7d7938cf31969e4cd347b0fc07330322b603c9ec0091b7a3f425132bed9dee6f261074cc273555120858beaaaf5da1")
provides=("sway" "swayfx" "wayland-compositor")
conflicts=("sway" "swayfx" "swayfx-git")
install=sway.install

build() {
        arch-meson \
                -Dwerror=false \
		-Dsd-bus-provider=libelogind \
                "swayfx-${pkgver}" build
        meson compile -C build
}

package() {
        install -Dm644 sway-portals.conf "$pkgdir/usr/share/xdg-desktop-portal/sway-portals.conf"

        DESTDIR="$pkgdir" meson install -C build

        cd "swayfx-${pkgver}"
        install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}