PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: Alex Gartner <aur@agartner.com>
pkgname=swaylock-dpms-git
pkgver=1.5.r12.g4870372
pkgrel=1
license=(custom:MIT)
pkgdesc='swaylock with dpms support'
url=https://github.com/gartnera/swaylock
arch=(x86_64)
provides=("swaylock=${pkgver%%.r*}")
conflicts=(swaylock)
depends=(cairo pam wayland gdk-pixbuf2 libxkbcommon)
makedepends=(meson ninja git wayland-protocols scdoc)
source=(
	"${pkgname}::git+https://github.com/gartnera/swaylock"
)

sha512sums=(
	'SKIP'
)

pkgver () {
	cd "${pkgname}"
	(
		set -o pipefail
		git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
		printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
	)
}

build () {
	cd "${pkgname}"

	rm -rf build
	meson build \
		--prefix /usr \
		--buildtype plain

	ninja -C build
}

package () {
	cd "${pkgname}"
	DESTDIR="${pkgdir}" ninja -C build install
	install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}