blob: f9a72808c474752dff24d076107946b66123fd1d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Francesco Minnocci <ascoli dot minnocci at gmail dot com>
# Contributor: Jason Ryan <jasonwryan@gmail.com>
# Contributor: Steven Allen <steven@stebalien.com>
# Contributor: Army
# Contributor: Bastien Dejean <baskerville@lavabit.com>
_name=sxiv
pkgname="${_name}-bachoseven-git"
pkgver=v26.r4.gf68fb4d
pkgrel=1
pkgdesc="Sxiv fork which opens all files in the input file's directory, with some custom bindings."
arch=('i686' 'x86_64')
url="https://github.com/BachoSeven/${_name}"
license=('GPL2')
depends=('imlib2' 'libexif' 'libxft' 'hicolor-icon-theme')
makedepends=('git')
provides=("${_name}")
conflicts=("${_name}")
source=("${_name}::git+${url}.git")
sha256sums=('SKIP')
pkgver() {
cd "${srcdir}/${_name}"
git describe --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${srcdir}/${_name}"
# Allow custom FLAGS
sed -i Makefile -e 's|^CFLAGS\s*=|CFLAGS +=|' -e 's|^LDFLAGS\s*=|LDFLAGS +=|'
}
build() {
cd "$srcdir/${_name}"
export CFLAGS="$CFLAGS $CPPFLAGS"
make PREFIX="/usr"
}
package() {
cd "$srcdir/${_name}"
make PREFIX="/usr" DESTDIR="$pkgdir" install
make -C icon PREFIX="/usr" DESTDIR="$pkgdir" install
install -Dm644 sxiv.desktop "$pkgdir/usr/share/applications/${_name}.desktop"
}
# vim:set ts=2 sw=2 et:
|