PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71

# Maintainer: Benedikt Heine <bebe@bebehei.de>

# Based on work of original synapse PKGBUILD from:
# - Felix Yan <felixonmars@archlinux.org>
# - Alessio Sergi <asergi at archlinux dot us>

_bzr_branch=trunk
_pkgname=synapse

pkgname=$_pkgname-bzr
pkgver=r653
pkgrel=1
pkgdesc="A semantic file launcher"
arch=('i686' 'x86_64')
url="https://launchpad.net/synapse-project"
license=('GPL3')

conflicts=(
           "$_pkgname"
          )

depends=(
         'libkeybinder3'
         'hicolor-icon-theme'
         'json-glib'
         'libgee'
         'libnotify'
         'zeitgeist'
         'rest'
         'xdg-utils'
        )
makedepends=(
             'intltool'
             'vala'
            )
optdepends=(
            'banshee: banshee plugin'
            'bc: calculator plugin'
            'devhelp: documentation plugin'
            'gnome-screensaver: screensaver plugin'
            'gnome-dictionary: dictionary plugin'
            'openssh: ssh plugin'
            'pastebinit: pastebin plugin'
            'rhythmbox: rhythmbox plugin'
            'xnoise: xnoise plugin'
           )

source=(
        "$_pkgname::bzr+http://bazaar.launchpad.net/~$_pkgname-core/$_pkgname-project/$_bzr_branch/"
       )
sha1sums=(
          'SKIP'
         )

pkgver() {
  cd "$_pkgname"
  printf "r%s" "$(bzr revno)"
}

build() {
  cd "$srcdir/$_pkgname"

  ./autogen.sh --prefix=/usr
  make
}

package() {
  cd "$srcdir/$_pkgname"

  make DESTDIR="$pkgdir/" install
}