blob: 5c57ebf8fc586a9ef89c51c8f41d750c13e114da (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Martin Kröning <m dot kroening at hotmail dot de>
# Contributor: Jan-Erik Rediger <badboy at archlinux dot us>
_realname=Sync-my-L2P
pkgname=sync-my-l2p
pkgver=2.4.1
pkgrel=2
pkgdesc='Sync the L2P and moodle instance of RWTH Aachen University'
arch=('x86_64')
url='https://syncmyl2p.de/'
license=('LGPL3')
depends=('hicolor-icon-theme' 'qt5-base')
_commit=b35e60690f68c376bed925dfe0fa605a3c9e9f17 # tags/v2.4.1^0
source=("git+https://github.com/RobertKrajewski/$_realname.git#commit=$_commit"
"https://github.com/RobertKrajewski/$_realname/releases/download/v$pkgver/SyncMyL2P-$pkgver-linux.AppImage")
sha256sums=('SKIP'
'a84527eadedea94144452f300883eef87880ee0608957dc44094cbd66e6d02c1')
prepare() {
# Setup client_id
chmod +x SyncMyL2P-$pkgver-linux.AppImage
./SyncMyL2P-$pkgver-linux.AppImage --appimage-extract usr/bin/$_realname
client_id=$(strings squashfs-root/usr/bin/$_realname | grep .apps.rwth-aachen.de)
sed --in-place "s/\(#define CLIENTID\) .*/\1 \"$client_id\"/g; /#error ERROR: NO CLIENTID IN CLIENTID.H DEFINED/d" "$srcdir"/$_realname/include/clientId.h
mkdir -p build
}
build() {
cd build
qmake ../${_realname}
make
}
package() {
cd build
# Binary
install -D -m0755 bin/$_realname "$pkgdir"/usr/bin/$_realname
cd ../${_realname}
# Desktop entry
install -D -m0644 linux/$_realname.desktop "$pkgdir"/usr/share/applications/$_realname.desktop
# Icons
mkdir --parents "$pkgdir"/usr/share/icons && cp --recursive linux/hicolor "$pkgdir"/usr/share/icons/
chmod --recursive 755 "$pkgdir"/usr/share/icons/hicolor
}
|