blob: b5b8f42d7fb3a4cde7171384e94020865540ae3b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Martin Kröning <m dot kroening at hotmail dot de>
# Contributor: Jan-Erik Rediger <badboy at archlinux dot us>
_realname=Sync-my-L2P
pkgname=sync-my-l2p
pkgver=2.4.2
pkgrel=1
pkgdesc='Sync the L2P and moodle instance of RWTH Aachen University'
arch=('x86_64')
url='https://syncmyl2p.de/'
license=('LGPL3')
depends=('qt5-base' 'hicolor-icon-theme')
source=("$_realname-$pkgver.tar.gz::https://github.com/RobertKrajewski/$_realname/archive/v$pkgver.tar.gz"
"https://github.com/RobertKrajewski/$_realname/releases/download/v$pkgver/SyncMyL2P-$pkgver-linux.AppImage")
sha256sums=('2e10daef909711f9894190e6c8d8856b43d0dde8ec3348a0e31d11628b1fb262'
'd157702966520c279ace87e190ca7a9e06fb89b74839903513f0d02d2ff90bd7')
prepare() {
# Setup client_id
chmod +x SyncMyL2P-$pkgver-linux.AppImage
./SyncMyL2P-$pkgver-linux.AppImage --appimage-extract usr/bin/$_realname
client_id=$(strings squashfs-root/usr/bin/$_realname | grep .apps.rwth-aachen.de)
cd "$_realname-$pkgver"
sed --in-place "s/\(#define CLIENTID\) .*/\1 \"$client_id\"/g; /#error ERROR: NO CLIENTID IN CLIENTID.H DEFINED/d" include/clientId.h
mkdir -p build
}
build() {
cd "$_realname-$pkgver/build"
qmake-qt5 ../$_realname.pro \
PREFIX=/usr \
QMAKE_CFLAGS="${CFLAGS}" \
QMAKE_CXXFLAGS="${CXXFLAGS}" \
QMAKE_LFLAGS="${LDFLAGS}"
make
}
package() {
cd "$_realname-$pkgver"
# Binary
install -D -m0755 build/bin/$_realname "$pkgdir"/usr/bin/$_realname
# Desktop entry
install -D -m0644 linux/$_realname.desktop "$pkgdir"/usr/share/applications/$_realname.desktop
# Icons
mkdir --parents "$pkgdir"/usr/share/icons && cp --recursive linux/hicolor "$pkgdir"/usr/share/icons/
chmod --recursive 755 "$pkgdir"/usr/share/icons/hicolor
}
|