blob: 66cf13e3dbd329e017313fc646101d3600fd0eef (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: jason ryan <jasonwryan@gmail.com>
# Contributor : Martin Wimpress <code@flexion.org>
pkgname=syncthing-bin
_realname=syncthing
pkgver=0.14.33
pkgrel=1
pkgdesc="Open Source Continuous Replication / Cluster Synchronization Thing: binary."
url="http://syncthing.net/"
arch=('any')
license=('MPLv2')
provides=('syncthing=0.14.33')
conflicts=('syncthing')
install=${_realname}.install
source=( 'syncthing.1')
sha256sums=('fb59747ca16d1b19e3cad1c147dcabea14a30a5e4177b90712e6bb837c107912')
case "$CARCH" in
arm*) _pkgarch="arm"
sha256sums+=('2e0211898fcb5c911e72926577f52319d7e75238276c9e76a909188513dc4a75')
;;
i686) _pkgarch="386"
sha256sums+=('5cccfe6b7b05c68ec287c129037a397a8f958b0ade22bf671029d13e701561ed')
;;
x86_64) _pkgarch="amd64"
sha256sums+=('5ad74da27b1825494bf76ef299887cc1a4b2fa94373fdff0dcf6724a28e3e041')
;;
esac
source+=("https://github.com/syncthing/${_realname}/releases/download/v${pkgver}/${_realname}-linux-${_pkgarch}-v${pkgver}.tar.gz")
package() {
cd "${_realname}-linux-${_pkgarch}-v${pkgver}"
install -D -m 755 ${_realname} "${pkgdir}/usr/bin/${_realname}"
install -D -m 644 LICENSE.txt "${pkgdir}/usr/share/licenses/${_realname}/LICENSE"
install -D -m 644 README.txt "${pkgdir}/usr/share/doc/${_realname}/README.md"
install -D -m 644 "etc/linux-systemd/system/${_realname}@.service" \
"${pkgdir}/usr/lib/systemd/system/${_realname}@.service"
install -D -m 644 "etc/linux-systemd/user/${_realname}.service" \
"${pkgdir}/usr/lib/systemd/user/${_realname}.service"
install -D -m 644 "../${_realname}.1" "${pkgdir}/usr/share/man/man1/${_realname}.1"
}
# vim:set ts=2 sw=2 et:
|