blob: 1a0d3a611594b338b7131c792da6f5ecc9e4df9f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer : Kevin MacMartin <prurigro@gmail.com>
_binname=stdiscosrv
_pkgname=syncthing
pkgname=$_pkgname-discosrv
epoch=1
pkgver=0.14.38
pkgrel=1
pkgdesc='Discover server for the syncthing P2P synchronization utility'
url='http://syncthing.net'
license=('MIT')
install=$pkgname.install
depends=('glibc')
makedepends=('git' 'go' 'godep' 'mercurial')
arch=('i686' 'x86_64' 'arm' 'armv6h' 'armv7h')
source=(
"https://github.com/$_pkgname/$_pkgname/archive/v$pkgver.tar.gz"
"$pkgname.service"
"$pkgname.tmpfiles.conf"
)
sha512sums=(
'be5f7527d63e8db427705c34b26d783d9abd7cb5727d3dcf08ee62b1ace5454b7dfed4f030ec53e847a34f560cf349460f68c859a1008c5105aef65ef42c5cc5'
'b2a8daa48be57ad47542569473128c8590d4bbe124de0912ce5b3de7deb1b54dd0d3ed66e925fc11addded075d24d6a1fe822d71338d128b7ca03fd43c082d8c'
'28b0bb6a6f2fa536ec8cb887cfebf4706be25af5e29da39e2e3776daeeeb48f75fb5be255472920355948d8905830342866e89299facd626ddf8a658d84faf27'
)
build() {
cd $_pkgname-$pkgver/cmd/$_binname
export GOPATH="$srcdir"
go get -d -tags purego
go build -i -v -ldflags -w
}
package() {
# Install systemd service and tmpfiles config
install -Dm644 $pkgname.service "$pkgdir/usr/lib/systemd/system/$pkgname.service"
install -Dm644 $pkgname.tmpfiles.conf "$pkgdir/usr/lib/tmpfiles.d/$pkgname.conf"
# Install license and list of authors
cd $_pkgname-$pkgver
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm644 AUTHORS "$pkgdir/usr/share/licenses/$pkgname/AUTHORS"
# Install the man page
install -Dm644 man/$_binname.1 "$pkgdir/usr/share/man/man1/$pkgname.1"
# Install the binary
install -Dm755 cmd/$_binname/$_binname "$pkgdir/usr/bin/$pkgname"
}
|