PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: Nomadcxx <noovie@gmail.com>
pkgname=sysc-walls
pkgver=1.0.1
pkgrel=1
pkgdesc="A terminal screensaver, designed in Go and built for Wayland"
arch=('x86_64' 'aarch64')
url="https://github.com/Nomadcxx/sysc-walls"
license=('GPL-3.0-only')
depends=('kitty' 'wayland')
makedepends=('go>=1.24' 'git')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/Nomadcxx/${pkgname}/archive/v${pkgver}.tar.gz")
sha256sums=('6dac75c831e7a743b388cbee34364d59e3797aab800f7850fa2e603114b92f0f')
install=${pkgname}.install

build() {
    cd "${srcdir}/${pkgname}-${pkgver}"

    export CGO_CPPFLAGS="${CPPFLAGS}"
    export CGO_CFLAGS="${CFLAGS}"
    export CGO_CXXFLAGS="${CXXFLAGS}"
    export CGO_LDFLAGS="${LDFLAGS}"
    export GOFLAGS="-buildmode=pie -trimpath -modcacherw"

    go build -buildvcs=false -o sysc-walls-daemon ./cmd/daemon/
    go build -buildvcs=false -o sysc-walls-display ./cmd/display/
    go build -buildvcs=false -o sysc-walls-client ./cmd/client/
}

package() {
    cd "${srcdir}/${pkgname}-${pkgver}"

    # Install binaries
    install -Dm755 sysc-walls-daemon "${pkgdir}/usr/bin/sysc-walls-daemon"
    install -Dm755 sysc-walls-display "${pkgdir}/usr/bin/sysc-walls-display"
    install -Dm755 sysc-walls-client "${pkgdir}/usr/bin/sysc-walls-client"

    # Install user service file (patch path for /usr/bin)
    install -d "${pkgdir}/usr/lib/systemd/user"
    sed 's|/usr/local/bin|/usr/bin|g' systemd/sysc-walls-user.service > "${pkgdir}/usr/lib/systemd/user/sysc-walls.service"
    chmod 644 "${pkgdir}/usr/lib/systemd/user/sysc-walls.service"

    # Install default ASCII art (bundled in repo)
    install -Dm644 assets/ascii/SYSC.txt "${pkgdir}/usr/share/sysc-walls/ascii/SYSC.txt"
    install -Dm644 assets/ascii/SYSC2.txt "${pkgdir}/usr/share/sysc-walls/ascii/SYSC2.txt"
    install -Dm644 assets/ascii/SYSC3.txt "${pkgdir}/usr/share/sysc-walls/ascii/SYSC3.txt"

    # Install README
    install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"

    # Install LICENSE
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}