blob: 0595bf5d814c710b13a6bef3ae36e98bab6defa9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Maintainer: Alexey D. <lq07829icatm@rambler.ru>
# Contributor: Dave Reisner <dreisner@archlinux.org>
# Contributor: Eric BĂ©langer <eric@archlinux.org>
# Contributor: Aaron Griffin <aaron@archlinux.org>
pkgname=syslog-ng-nosystemd
pkgver=3.19.1
pkgrel=3
pkgdesc="Next-generation syslogd with advanced networking and filtering capabilities"
arch=('i686' 'x86_64')
license=('GPL2' 'LGPL2.1')
groups=('eudev-base')
url="https://www.syslog-ng.com/products/open-source-log-management/"
depends=('awk' 'glib2' 'libcap' 'libdbi' 'libnsl' 'udev')
makedepends=('flex' 'pkg-config' 'libxslt' 'json-c' 'mongo-c-driver'
'librabbitmq-c' 'python' 'libesmtp' 'hiredis')
optdepends=('logrotate: for rotating log files'
'json-c: for json-plugin'
'curl: for the HTTP module'
'librabbitmq-c: for the AMQP plugin'
'mongo-c-driver: for the MongoDB plugin'
'python: for the Python plugin'
'libesmtp: for the SMTP plugin'
'hiredis: fir the redis plugin'
'syslog-ng-openrc: syslog-ng openrc initscript')
provides=("syslog-ng=${pkgver}")
replaces=('syslog-ng' 'syslog-ng-eudev' 'eventlog')
conflicts=('syslog-ng' 'syslog-ng-eudev' 'eventlog')
backup=('etc/syslog-ng/scl.conf'
'etc/syslog-ng/syslog-ng.conf'
'etc/conf.d/initscripts/syslog-ng'
'etc/logrotate.d/syslog-ng')
source=(https://github.com/balabit/syslog-ng/releases/download/syslog-ng-$pkgver/syslog-ng-$pkgver.tar.gz
syslog-ng.conf
syslog-ng.conf.d
syslog-ng.logrotate
syslog-ng.rc)
sha256sums=('5cf931a9d7bead0e6d9a2c65eee8f6005a005878f59aa280f3c4294257ed5178'
'0610bc3900453329c1ea68f3ad5a4ef49b8f4d2199e1a380389adcc760babf34'
'fe6ebe5c281b34bad201d9206e607857db9a5a78f03bb4dc4440584dca610f61'
'93c935eca56854011ea9e353b7a1da662ad40b2e8452954c5b4b5a1d5b2d5317'
'db643d69e840dfd5d7849e857291f15fd60913527402fde806ce3911e3523063')
build() {
cd "syslog-ng-$pkgver"
./configure \
--prefix=/usr \
--sysconfdir=/etc/syslog-ng \
--libexecdir=/usr/lib \
--sbindir=/usr/bin \
--localstatedir=/var/lib/syslog-ng \
--datadir=/usr/share \
--with-pidfile-dir=/run \
--disable-spoof-source \
--enable-ipv6 \
--enable-sql \
--enable-smtp \
--enable-manpages \
--with-jsonc=system \
--with-mongoc=system \
--with-librabbitmq-client=system \
--disable-systemd
make
}
package() {
make -C "syslog-ng-$pkgver" DESTDIR="$pkgdir" install
install -dm755 "$pkgdir/var/lib/syslog-ng" "$pkgdir/etc/syslog-ng/patterndb.d"
install -Dm644 "$srcdir/syslog-ng.conf" "$pkgdir/etc/syslog-ng/syslog-ng.conf"
install -Dm644 "$srcdir/syslog-ng.logrotate" "$pkgdir/etc/logrotate.d/syslog-ng"
install -Dm755 "$srcdir/syslog-ng.rc" "$pkgdir/etc/rc.d/syslog-ng"
install -Dm644 "$srcdir/syslog-ng.conf.d" "$pkgdir/etc/conf.d/initscripts/syslog-ng"
# See http://lists.balabit.hu/pipermail/syslog-ng/2016-February/022667.html
rm -r "$pkgdir/usr/share/syslog-ng/include/scl/cim"
}
|