blob: 6acf567e0ddaf34441a258168c939ab46e029552 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: Dwayne Bent <dbb@dbb.io>
pkgname=systemd-cron
pkgver=1.5.3
pkgrel=1
pkgdesc='systemd units to run cron scripts'
arch=(any)
url='https://github.com/systemd-cron/systemd-cron'
license=('MIT')
depends=('systemd>=217' 'run-parts' 'python')
optdepends=('smtp-forwarder: sending emails')
provides=('cron')
conflicts=('cron')
source=("https://github.com/systemd-cron/${pkgname}/archive/v${pkgver}.tar.gz")
install=${pkgname}.install
md5sums=('15da1cb2e1171d24927e3241de6f7969')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr --confdir=/etc \
--enable-minutely --enable-quarterly --enable-semi_annually --enable-yearly \
--enable-persistent --enable-setgid
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -d "${pkgdir}"/etc/cron.{boot,minutely,hourly,daily,weekly,monthly,quarterly,semi-annually,yearly}
install -d "${pkgdir}"/var/spool/cron
}
|