blob: 92c5f937b944862aee65977ebdf2f7761abbddb6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Antonio Rojas <nqn1976 @ gmail.com>
pkgname=systemsettings-git
pkgver=r1459.a19881d
pkgrel=1
pkgdesc='KDE system settings'
arch=('i686' 'x86_64')
url='https://projects.kde.org/projects/kde/kde-workspace'
license=('LGPL')
depends=('kcmutils-git' 'khtml-git')
makedepends=('extra-cmake-modules-git' 'git' 'kdoctools' 'python')
conflicts=('systemsettings' 'kde-workspace<0')
provides=('systemsettings')
source=('git://anongit.kde.org/systemsettings.git')
groups=('plasma')
md5sums=('SKIP')
pkgver() {
cd systemsettings
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
mkdir -p build
}
build() {
cd build
cmake ../systemsettings \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DLIB_INSTALL_DIR=lib \
-DKDE_INSTALL_USE_QT_SYS_PATHS=ON
make
}
package() {
cd build
make DESTDIR="${pkgdir}" install
}
|