blob: ecaa39d02e936d40c49ca83b03e5694c69607864 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: lilydjwg <lilydjwg@gmail.com>
# Maintainer: Shang Yuanchun <idealities@gmail.com>
pkgname=systemtap-git
pkgver=4.0.86.g3a29a2eef
pkgrel=1
pkgdesc="provides infrastructure to simplify the gathering of information about the running Linux system."
url="http://sourceware.org/systemtap/"
arch=('i686' 'x86_64')
license=('GPL')
depends=('elfutils' 'nss' 'python' 'json-c' 'avahi' 'readline' 'nspr')
makedepends=('git' 'python-setuptools' 'xmlto' 'cpio')
optdepends=('sqlite')
provides=(systemtap=4.0)
conflicts=(systemtap)
_gitroot=https://sourceware.org/git/systemtap.git
_gitname=systemtap
source=("git+$_gitroot"
remove-install-exec-hook.patch)
md5sums=('SKIP'
'6db56245ab316134c9a487e16ea52084')
install=systemtap.install
pkgver() {
cd "$srcdir/$_gitname"
git describe | sed 's/release-//;s/-/./g'
}
prepare() {
cd "$srcdir/$_gitname"
patch -p1 -i "$srcdir"/remove-install-exec-hook.patch
}
build() {
cd "$srcdir/$_gitname"
msg "Starting make..."
# docs failed to build
./configure \
--prefix=/usr \
--sbindir=/usr/bin \
--sysconfdir=/etc \
--localstatedir=/var \
--libdir=/usr/lib/"${_gitname}" \
--libexecdir=/usr/lib/"${_gitname}" \
--with-python3 \
--enable-pie \
--disable-docs \
--enable-htmldocs
make
}
package() {
cd "$srcdir/$_gitname"
make DESTDIR="${pkgdir}" install
cd "${pkgdir}"
pushd var >/dev/null
rmdir -p run/stap-server log
popd >/dev/null
rmdir var
}
|