PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# $Id: PKGBUILD 203202 2014-01-05 10:51:18Z bpiotrowski $
# Maintainer: Nikos Fytilis <n-fit@live.com>
# Repo Maintainer: Daniel Isenmann <daniel@archlinux.org>
# Contributor: Carlos Ruiz <cailovirtual@gmail.com>

_pkgbase=taglib-sharp
pkgname=$_pkgbase-git
pkgver=2.1.0.0.r168.gab86113
pkgrel=1
pkgdesc="Library for reading and writing metadata in media files for Mono - source from git for working opus files"
arch=('i686' 'x86_64')
url="https://github.com/mono/taglib-sharp"
license=('LGPL2.1')
depends=('mono')
conflicts=(taglib-sharp)
provides=("taglib-sharp=${pkgver%%.r*}")
source=(git+https://github.com/mono/taglib-sharp.git
sign.patch)
md5sums=('SKIP'
         'fb6bb9fc76b88a449fb1466569194da0')
pkgver() {
  cd "$srcdir/$_pkgbase"
  git describe --long | sed 's/^taglib-sharp-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "$srcdir/$_pkgbase"
#  git reset --hard 2ab021d38a561e09e95d85212765cbec141bbd7f
  patch src/Makefile.am "$srcdir/sign.patch"
}

build() {
  cd "$srcdir/$_pkgbase"
  ./autogen.sh --prefix=/usr --disable-docs
  make
}

package() {
  cd "$srcdir/$_pkgbase"
  make DESTDIR=${pkgdir} install
}