blob: 70e827690c9ab8a5e5fef86f2c5e2b32f4d7a1e3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
pkgname="talm"
pkgver=0.16.0
pkgrel=1
pkgdesc="Manage Talos Linux the GitOps Way!"
arch=('aarch64' 'i686' 'x86_64')
url="https://github.com/cozystack/${pkgname}"
license=('MPL-2.0')
depends=('glibc')
makedepends=('go')
_pkgsrc="${pkgname}-${pkgver}"
source=("${_pkgsrc}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('05a794e7f8ef38fb5bd059c6eb52064ba9c084c2c55509cf2af0fdb369e2fb62')
prepare() {
export GOMODCACHE="${srcdir}/go-mod-cache"
cd "${srcdir}/${_pkgsrc}"
go mod download -x
find "${GOMODCACHE}" -type d -exec chmod 755 {} +
find "${GOMODCACHE}" -type f -exec chmod 644 {} +
mkdir -p "build" "completions"
}
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOCACHE="${srcdir}/go-cache"
export GOMODCACHE="${srcdir}/go-mod-cache"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
cd "${srcdir}/${_pkgsrc}"
go build -v -o "build/${pkgname}" -ldflags "\
-X main.Version=${pkgver}" \
.
for _sh in bash fish zsh powershell; do
./"build/${pkgname}" completion "${_sh}" > "completions/${pkgname}.${_sh}"
done
}
# check() {
# cd "${srcdir}/${_pkgsrc}"
# go test ./...
# }
package() {
cd "${srcdir}/${_pkgsrc}"
install -vDm755 "build/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
cd "completions"
install -vDm644 "${pkgname}.bash" "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
install -vDm644 "${pkgname}.fish" "${pkgdir}/usr/share/fish/vendor_completions.d/${pkgname}.fish"
install -vDm644 "${pkgname}.zsh" "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
install -vDm644 "${pkgname}.powershell" "${pkgdir}/usr/share/powershell/Completions/${pkgname}.ps1"
}
|