blob: b0ae56dfbae9658fb707f6009d94c5ac267b514a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Henry Graham <henry)dot(arch)at(hgrahamcs)dot(com(>
# Contributor: Sébastien "Seblu" Luttringer <seblu@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Andreas Radke <andyrtr@archlinux.org>
_appname_=tar
pkgname=tar-parallel
pkgver=1.33
pkgrel=1
pkgdesc='Utility used to store, backup, and transport files with parallel compression'
arch=('x86_64')
url='https://www.gnu.org/software/tar/'
license=('GPL3')
depends=('glibc' 'acl' 'attr' 'pigz' 'pbzip2')
options=('!emptydirs')
validpgpkeys=('325F650C4C2B6AD58807327A3602B07F55D0C732') # Sergey Poznyakoff
source=("https://ftp.gnu.org/gnu/${_appname_}/${_appname_}-$pkgver.tar.xz"{,.sig})
md5sums=('e536d6621f9ad06df65c177348bb1215'
'SKIP')
provides=('tar')
conflicts=('tar')
prepare() {
cd ${_appname_}-$pkgver
# apply patch from the source array (should be a pacman feature)
local src
for src in "${source[@]}"; do
src="${src%%::*}"
src="${src##*/}"
[[ $src = *.patch ]] || continue
msg2 "Applying patch $src..."
patch -Np1 < "../$src"
done
:
}
build() {
cd ${_appname_}-$pkgver
./configure --prefix=/usr --libexecdir=/usr/lib/tar --with-gzip=pigz --with-bzip2=pbzip2
make
}
check() {
cd ${_appname_}-$pkgver
make check
}
package() {
cd ${_appname_}-$pkgver
make DESTDIR="$pkgdir" install
}
|