blob: d0f3fd1b51ffde5403557c1ef3dd908319e9f90d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: AtticFinder65536 <atticfinder -AT- rocklabs -DOT- xyz>
# Contributor: Johannes Schlatow <johannes.schlatow@googlemail.com>
# Contributor: Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: Orhun Parmaksız <orhun@archlinux.org>
# Contributor: Peter Lewis <plewis@aur.archlinux.org>
# Contributor: TDY <tdy@gmx.com>
# Contributor: Ray Kohler <ataraxia@gmail.com>
# Contributor: muflax <muflax@gmail.com>
# Contributor: coolkehon <coolkehon@gmail.com>
pkgname=task-git
pkgver=2.6.2.r916.g0adced7
pkgrel=1
epoch=1
pkgdesc="A command-line todo list manager"
arch=('i686' 'x86_64')
url="https://taskwarrior.org/"
license=('MIT')
depends=('util-linux' 'gnutls')
makedepends=('cmake' 'git' 'cargo')
optdepends=('bash-completion: for bash completion'
'python: for python export addon'
'ruby: for ruby export addon'
'perl: for perl export addon'
'perl-json: for perl export addon')
source=("git+https://github.com/GothenburgBitFactory/taskwarrior.git#branch=develop"
"git+https://github.com/GothenburgBitFactory/libshared.git"
"git+https://github.com/Devolutions/CMakeRust.git")
b2sums=('SKIP'
'SKIP'
'SKIP')
provides=('task')
conflicts=('task')
prepare() {
cd taskwarrior
git submodule init
git config submodule.src/libshared.url "$srcdir/libshared"
git config submodule.cmake/CMakeRust.url "$srcdir/CMakeRust"
git -c protocol.file.allow=always submodule update
}
pkgver() {
cd taskwarrior
git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd taskwarrior
cmake -DCMAKE_INSTALL_PREFIX=/usr .
make
}
package() {
cd taskwarrior
make DESTDIR="$pkgdir" install
# Note that we rename the bash completion script for bash-completion > 1.99, until upstream does so.
install -Dm644 "$pkgdir/usr/share/doc/task/scripts/bash/task.sh" "$pkgdir/usr/share/bash-completion/completions/task"
install -Dm644 "$pkgdir/usr/share/doc/task/scripts/fish/task.fish" "$pkgdir/usr/share/fish/vendor_completions.d/task.fish"
install -Dm644 "$pkgdir/usr/share/doc/task/scripts/vim/ftdetect/task.vim" "$pkgdir/usr/share/vim/vimfiles/ftdetect/task.vim"
install -Dm644 "$pkgdir/usr/share/doc/task/scripts/vim/syntax/taskdata.vim" "$pkgdir/usr/share/vim/vimfiles/syntax/taskdata.vim"
install -Dm644 "$pkgdir/usr/share/doc/task/scripts/vim/syntax/taskedit.vim" "$pkgdir/usr/share/vim/vimfiles/syntax/taskedit.vim"
install -Dm644 "$pkgdir/usr/share/doc/task/scripts/vim/syntax/taskrc.vim" "$pkgdir/usr/share/vim/vimfiles/syntax/taskrc.vim"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|