blob: 25cfef45a9c75ae39ffab7fdcc00a94ad29a43ad (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
|
# Maintainer: Adrián Pérez de Castro <aperez@igalia.com>
pkgname=task-indicator-git
pkgdesc='Panel indicator for TaskWarrior'
pkgver=r163.7322dd8
pkgrel=1
url=https://github.com/umonkey/task-indicator
license=(custom:MIT)
arch=(any)
depends=(python2 hicolor-icon-theme python2-gobject2)
optdepends=('libappindicator-gtk2: Application indicator support')
conflicts=(task-indicator taskwarrior-indicator-hg)
provides=("${conflicts[@]}")
replaces=(taskwarrior-indicator-hg)
source=("${pkgname}::git+${url}")
sha512sums=(SKIP)
pkgver () {
cd "${pkgname}"
(
set -o pipefail
git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
package () {
cd "${pkgname}"
python2 setup.py install --root="${pkgdir}"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|