PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Maintainer: DonutsDelivery
pkgname=task-manager-linux-bin
pkgver=0.3.1
pkgrel=1
pkgdesc="GTK4/libadwaita system task manager and performance monitor for Linux"
arch=('x86_64')
url="https://github.com/DonutsDelivery/task-manager-linux"
license=('MIT')
depends=('gtk4' 'libadwaita' 'dbus')
optdepends=(
    'nvidia-utils: NVIDIA GPU monitoring via NVML'
    'lm_sensors: CPU temperature monitoring'
)
provides=('task-manager-linux')
conflicts=('task-manager-linux')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/DonutsDelivery/task-manager-linux/releases/download/v${pkgver}/task-manager-linux-x86_64.tar.gz")
sha256sums=('21b68c4c8b08cc70231f3466678017fcecf2e8114b99c82ce06cb059d6759511')

package() {
    install -Dm755 "${srcdir}/task-manager-linux" "${pkgdir}/usr/bin/task-manager-linux"

    # Icon
    install -Dm644 "${srcdir}/task-manager-linux.svg" "${pkgdir}/usr/share/icons/hicolor/scalable/apps/task-manager-linux.svg"

    # Desktop entry
    install -Dm644 /dev/stdin "${pkgdir}/usr/share/applications/task-manager-linux.desktop" << DESKTOP
[Desktop Entry]
Type=Application
Name=Task Manager
GenericName=System Monitor
Comment=System process manager and performance monitor
Exec=task-manager-linux
Icon=task-manager-linux
Terminal=false
Categories=System;Monitor;
Keywords=task;process;system;monitor;cpu;memory;gpu;
StartupNotify=true
DESKTOP
}