blob: 5f46f2fafaf4344fbe39c8e346cf104ba6e24d2f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=tcsh-git
pkgver=6.24.10.r9.g360a97d
pkgrel=1
pkgdesc="C shell with file name completion and command line editing"
arch=('i686' 'x86_64')
url="https://www.tcsh.org/"
license=('BSD-3-Clause')
depends=('glibc' 'libxcrypt' 'ncurses')
makedepends=('git')
provides=("tcsh=$pkgver")
conflicts=('tcsh')
backup=('etc/csh.cshrc'
'etc/csh.login')
install=tcsh.install
source=("git+https://github.com/tcsh-org/tcsh.git"
"csh.cshrc::https://gitlab.archlinux.org/archlinux/packaging/packages/tcsh/-/raw/main/csh.cshrc"
"csh.login::https://gitlab.archlinux.org/archlinux/packaging/packages/tcsh/-/raw/main/csh.login")
sha256sums=('SKIP'
'SKIP'
'SKIP')
pkgver() {
cd "tcsh"
git describe --long --tags | sed 's/^TCSH//;s/\([^-]*-g\)/r\1/;s/[-_]/./g'
}
build() {
cd "tcsh"
autoreconf -fi
./configure \
--prefix="/usr"
make
}
check() {
cd "tcsh"
make check
}
package() {
cd "tcsh"
make DESTDIR="$pkgdir" install
ln -s "tcsh" "$pkgdir/usr/bin/csh"
ln -s "tcsh.1" "$pkgdir/usr/share/man/man1/csh.1"
install -Dm644 "$srcdir"/csh.{cshrc,login} -t "$pkgdir/etc"
install -Dm644 "Copyright" -t "$pkgdir/usr/share/licenses/tcsh"
}
|