blob: 54d23e3c6ba35ef508de9bb623a8b4693f10a130 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: su226 <thesu226 at outlook dot com>
pkgname=techmino
pkgver="0.17.16"
_ccloader_ver="11.4.2"
_coldclear_ver="23c1cd6e4aa44f2a61daa839ae08dfd3cd5f9da3"
pkgrel=1
epoch=
pkgdesc="A collection of various modern block game rules, more ways to play, and some new things added for a new experience."
arch=(x86_64)
# HTTPS cert of https://www.studio26f.org has expired since 2023-11-29 :/
url="https://github.com/26F-Studio/Techmino"
license=("LGPL3")
groups=()
depends=(love)
# Build ColdClear depends rust.
makedepends=(git rust)
checkdepends=()
optdepends=()
provides=()
conflicts=()
replaces=()
backup=()
options=()
install=
changelog=
source=("techmino-$pkgver.tar.gz::https://github.com/26F-Studio/Techmino/archive/refs/tags/v$pkgver.tar.gz"
"ccloader-$_ccloader_ver.tar.gz::https://github.com/26F-Studio/cold_clear_ai_love2d_wrapper/archive/refs/tags/$_ccloader_ver.tar.gz"
"git+https://github.com/26F-Studio/cold-clear.git#tag=$_coldclear_ver"
"techmino.sh"
"techmino.desktop")
noextract=()
sha256sums=("dc53bb84181e2a796be04c8e264ccef018f92a04a72eb1079ed913bd69c78219"
"dc70324e88927763cc68eb86f73374a585d63cdb9773f2776c4ed679944742b5"
SKIP
"9c8ac53a1264722b037ee8c72f5d0bc187ef9d106a3c2f949fb20537fb4c95f7"
"d08469240ce6e919f250a205a47b9916bbdb464604d198f4fb8b37b91212da5e")
validpgpkeys=()
prepare() {
cd "$srcdir/cold_clear_ai_love2d_wrapper-$_ccloader_ver"
rmdir cold-clear
ln -s ../cold-clear .
}
build() {
cd "$srcdir/cold_clear_ai_love2d_wrapper-$_ccloader_ver"
make build/Linux/x64/CCloader.so
cd "$srcdir/Techmino-$pkgver"
ln -sf ../../.github/build/linux/release/icon.png media/image/icon.png
bsdtar --format zip --exclude-vcs -Lcf techmino.love media parts Zframework conf.lua main.lua version.lua
}
package() {
install -Dm644 "$srcdir/cold_clear_ai_love2d_wrapper-$_ccloader_ver/build/Linux/x64/CCloader.so" "$pkgdir/usr/lib/techmino/CCloader.so"
install -Dm644 "$srcdir/Techmino-$pkgver/techmino.love" "$pkgdir/usr/lib/techmino/techmino.love"
install -Dm755 "$srcdir/techmino.sh" "$pkgdir/usr/lib/techmino/techmino"
install -Dm644 "$srcdir/techmino.desktop" "$pkgdir/usr/share/applications/techmino.desktop"
install -Dm644 "$srcdir/Techmino-$pkgver/.github/build/linux/release/icon.png" "$pkgdir/usr/share/icons/hicolor/256x256/apps/techmino.png"
install -Dm644 "$srcdir/Techmino-$pkgver/license.txt" "$pkgdir/usr/share/licenses/techmino/LICENSE"
install -Dm644 "$srcdir/Techmino-$pkgver/legals.md" "$pkgdir/usr/share/licenses/techmino/LICENSE-THIRD-PARTY"
mkdir -p "$pkgdir/usr/bin"
ln -s "/usr/lib/techmino/techmino" "$pkgdir/usr/bin/techmino"
}
|