PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Maintainer of this PKGBUILD file: Martino Pilia <martino.pilia@gmail.com>
_pkgname=teem
pkgname=${_pkgname}-svn
pkgver=r6479
pkgrel=1
pkgdesc='Group of libraries for processing scientific raster data.'
arch=('x86_64')
url='http://teem.sourceforge.net/index.html'
license=('LGPL')
depends=()
optdepends=()
makedepends=(
    'cmake'
    'svn'
)
source=(
    "${_pkgname}::svn+https://svn.code.sf.net/p/teem/code/teem/trunk"
)
sha256sums=("SKIP")

prepare() {
    cd "$srcdir/$_pkgname"

    rm -rf build
    mkdir build
    cd build

    cmake \
        -DCMAKE_INSTALL_PREFIX:PATH="/usr" \
        -DCMAKE_BUILD_TYPE:STRING=Release \
        -DBUILD_SHARED_LIBS:BOOL=ON \
        ..
}

pkgver() {
    cd "$srcdir/$_pkgname"
    local ver
    ver="$(svnversion)"
    printf "r%s" "${ver//[[:alpha:]]}"
}

build() {
    cd "$srcdir/$_pkgname/build"
    make
}

package() {
    cd "$srcdir/$_pkgname/build"
    make install DESTDIR="$pkgdir"

    install -D -m644 \
        "${srcdir}/$_pkgname/LICENSE.txt" \
        "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}