blob: d20dd7d92f1bf76f8c4165502f2fa7e6efba6f20 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# Maintainer: Niels Martignène <niels.martignene@gmail.com>
# Contributor: PyroPeter <googlemail.com@abi1789>
# Contributor: darkapex <me@jailuthra.in>
# Contributor: tty0 <vt.tty0[d0t]gmail.com>
pkgname=teensyduino
pkgver=1.53
arduinover=1.8.13
pkgrel=1
pkgdesc="Arduino SDK with Teensyduino"
arch=('x86_64')
url="http://www.pjrc.com/teensy/teensyduino.html"
options=(!strip staticlibs)
license=('GPL' 'LGPL' 'custom')
depends=('gtk2' 'libusb-compat' 'libusb' 'java-runtime' 'libpng12' 'libsm'
'desktop-file-utils' 'giflib')
makedepends=('git')
provides=('arduino')
conflicts=('arduino' 'teensy-loader-cli')
install="teensyduino.install"
source=('arduino.xml'
'teensy-loader.desktop'
"git+https://github.com/PaulStoffregen/teensy_loader_cli.git#commit=e98b5065cdb9f04aa4dde3f2e6e6e6f12dd97592"
"http://www.pjrc.com/teensy/49-teensy.rules"
'LICENSE'
"http://downloads.arduino.cc/arduino-${arduinover}-linux64.tar.xz"
"TeensyduinoInstall_${pkgver//./}_x86_64::http://www.pjrc.com/teensy/td_${pkgver//./}/TeensyduinoInstall.linux64")
sha256sums=('473b82156505e9bd903e4d8484e8d183f2e3bf3c1f7e29940b815929ae597b68'
'837a865ab3bf81163c95a8a5898f9d5f0de7740a4207949bc331409cbb40faba'
'SKIP'
'7c17bb6dcef244fbf8bc9bd85a7eb812eebe60f6a6a3d47bceddde84c77c5914'
'25980feb5927b8bea8b8e999f5002e110825b1bc3d546fa902c2db5c824d33f3'
'1b20d0ec850a2a63488009518725f058668bb6cb48c321f82dcf47dc4299b4ad'
'2e6cd99a757bc80593ea3de006de4cc934bcb0a6ec74cad8ec327f0289d40f0b')
build() {
msg2 "Installing Teensyduino"
chmod +x "TeensyduinoInstall_${pkgver//./}_${CARCH}"
./TeensyduinoInstall_${pkgver//./}_${CARCH} --dir="${srcdir}/arduino-${arduinover}"
msg2 "Building Teensy Loader command line"
cd teensy_loader_cli
make
}
package() {
cd "arduino-${arduinover}"
mkdir -p "${pkgdir}/usr/bin"
mkdir -p "${pkgdir}/usr/share/"{doc,applications,icons/hicolor,mime/packages,licenses/teensyduino}
mkdir -p "${pkgdir}/usr/lib/udev/rules.d"
# copy the whole SDK to /usr/share/arduino/
cp -a . "${pkgdir}/usr/share/arduino"
# use system's RXTX library
ln -sf /usr/lib/librxtxSerial.so "${pkgdir}/usr/share/arduino/lib/librxtxSerial.so"
ln -sf /usr/lib/librxtxSerial.so "${pkgdir}/usr/share/arduino/lib/librxtxSerial64.so"
ln -sf /usr/share/java/rxtx/RXTXcomm.jar "${pkgdir}/usr/share/arduino/lib/RXTXcomm.jar"
# we don't need these sources
rm -rf "${pkgdir}/usr/share/arduino/src"
# at least support the FHS a little bit
ln -s /usr/share/arduino/arduino "${pkgdir}/usr/bin/arduino"
ln -s /usr/share/arduino/reference "${pkgdir}/usr/share/doc/arduino"
# desktop icon
cp -a lib/icons/* "${pkgdir}/usr/share/icons/hicolor"
rm -rf "${pkgdir}/usr/share/arduino/lib/icons"
ln -s /usr/share/icons/hicolor "${pkgdir}/usr/share/arduino/lib/icons"
# desktop and mimetype files
sed "s,<BINARY_LOCATION>,arduino %U,g;s,<ICON_NAME>,arduino,g" lib/desktop.template > "${pkgdir}/usr/share/applications/arduino.desktop"
install -m644 "${srcdir}/arduino.xml" "${pkgdir}/usr/share/mime/packages/"
# install custom PJRC license
install -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/teensyduino/"
# install teensy loader files
install -m644 "${srcdir}/49-teensy.rules" "${pkgdir}/usr/lib/udev/rules.d"
ln -s /usr/share/arduino/hardware/tools/teensy "${pkgdir}/usr/bin/teensy-loader"
install -m644 "${srcdir}/teensy-loader.desktop" "${pkgdir}/usr/share/applications/"
# install command-line teensy loader
install -m755 "${srcdir}/teensy_loader_cli/teensy_loader_cli" "${pkgdir}/usr/bin/teensy-loader-cli"
}
|